有没有办法通过Jenkins脚本控制台用groovy脚本清理Jenkins Worflowjob工作区？

Question

这个问题似乎被问了多次，但所有答案都与Jenkins Pipeline jobs（插件：workflow job）有关。

我正在将一堆旧的自由式作业从旧的Jenkins独立服务器迁移到分布式Jenkinsenv，我决定将它们转换为Jenkins管道作业（不能使用Blue Ocean，因为SCM是SVN。

无论如何，对于某些作业来说，不希望清理它们的工作空间，因为它们是某种健全/验证作业，而且因为SVN签出和构建的内容的大小很大（20K文件中有2GB，只是删除它太慢）。

然而，我确实偶尔（临时）需要删除此类作业的工作区。我不想这样做：

• 修改Jenkinsfile并将其提交给SVN
• "重放"管道运行修改

我没有对从节点上的FS的r/w访问权限（这是最容易做到的）。

互联网上的快速搜索给我带来了大量结果[1,2,3,4，…]如何从Jenkins脚本控制台运行的Groovy脚本中清除WS（）。

不幸的是，它们都没有尝试删除作业的trueorg.jenkinsci.plugins.workflow.job.Workflow Jobs项实例的工作区。

基于从互联网上收集到的答案，我启动了我的Groovy清理脚本，可以从Jenkins脚本控制台

import hudson.model.*
import com.cloudbees.hudson.*
import com.cloudbees.hudson.plugins.*
import com.cloudbees.hudson.plugins.folder.*
import org.jenkinsci.plugins.workflow.job.*

//jobsToRetrieve = ["aFolder/aJobInFolder","topLevelJob"]
jobsToRetrieve = ["Sandbox/PipelineTests/SamplePipeline"]

enumerateItems(Hudson.instance.items)

def enumerateItems(items) {
  items.each { item ->
    println("===============::: GENERAL INFO::: =======================")
    println(" item: " + item)
    println(" item FN:  " + item.fullName)
    println(" item.getClass " + item.getClass())
    println("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~")

    if ( !(item instanceof Folder)) {
      jobName = item.getFullDisplayName()
      println(" :::jobname::: " + jobName)
      if (jobsToRetrieve.contains(item.getFullName())) {
        if (item instanceof WorkflowJob) {
          println("XXXXXXXXXXXXX--- THIS IS THE JOB --- XXXXXXXXXXXXXXXXXXXXX")
          println(" item.workspace: " + item.WORKSPACE)
          println("XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX")
          println(" following methods ain't implemented for WorkflowJob type of Item\nand it will blow out.")
          //see https://javadoc.jenkins.io/hudson/model/FreeStyleProject.html
          println(" customWS: " + item.getCustomWorkspace())
          println(" WS:" + item.getWorkspace())
          item.doDoWipeOutWorkspace()
        }
      }
    } else {
        println(" :::foldername::: " + item.displayName)
        enumerateItems(((Folder) item).getItems())
    }
    println("==========================================================")
  }
}

如您所见，我的脚本将在以下调用中爆炸：

item.getCustomWorkspace()
item.getWorkspace()
item.doDoWipeOutWorkspace()

带有MissingMethodException

groovy.lang.MissingMethodException: No signature of method: org.jenkinsci.plugins.workflow.job.WorkflowJob.doDoWipeOutWorkspace() is applicable for argument types: () values: []
    at org.codehaus.groovy.runtime.ScriptBytecodeAdapter.unwrap(ScriptBytecodeAdapter.java:58)
    at org.codehaus.groovy.runtime.callsite.PojoMetaClassSite.call(PojoMetaClassSite.java:49)
    at org.codehaus.groovy.runtime.callsite.CallSiteArray.defaultCall(CallSiteArray.java:48)
    at org.codehaus.groovy.runtime.callsite.AbstractCallSite.call(AbstractCallSite.java:113)
    at org.codehaus.groovy.runtime.callsite.AbstractCallSite.call(AbstractCallSite.java:117)
    at Script1$_enumerateItems_closure1.doCall(Script1.groovy:33)

只是因为这些方法不适用于此类项目，而仅适用于hudson。模型自由泳项目

还有另一个Jenkins插件：Workspace Cleanup可能在Jenkinsfile中使用，方法是在阶段() {}内调用清洁Ws（），但我不知道如何从Jenkinsfile外部使用它（就像从我Jenkins脚本控制台运行的groovy脚本一样）。

这是一个错误/请求增强Jenkins管道作业插件？或者有任何其他方法如何将项目转换为我可以访问所需功能的东西？




Answer 1

这不是最漂亮的方法，但您可以执行OS命令：

def isWin = Jenkins.instance.windows
def cmd = isWin ? "rmdir /s /q $workspace" : "rm -rf $workspace"

cmd.execute()

如果您只使用一次代码或不处理多个操作系统，您可以将代码缩短为相应的命令：

"rm -rf $workspace".execute()

Answer 2

好吧，更多地调查这件事，更多地用谷歌搜索，倾听你的想法（这件事特别是丹尼尔·斯皮尔克启发了我），我已经实现了我想要的，那就是：

（仅使用Jenkins可用的方法，并且不会弄乱作业配置，也不会更新Jenkins文件，也不会重播）

代码的难度并不出人意料，对于手动演示，它看起来是这样的：

Jenkins jenkins = Jenkins.instance
Job item = jenkins.getItemByFullName('Sandbox/PipelineTests/SamplePipeline')
println("RootDir: " + item.getRootDir())

for (Node node in jenkins.nodes) {
  // Make sure slave is online
  if (!node.toComputer().online) {
    println "Node '$node.nodeName' is currently offline - skipping workspace cleanup"
    continue
  }

  println "Node '$node.nodeName' is online - performing cleanup:"

  // Do some cleanup
  FilePath wrksp = node.getWorkspaceFor(item)
  println("WRKSP "  + wrksp)
  println("ls " + wrksp.list())
  println("Free space " + wrksp.getFreeDiskSpace())
  println("===== PERFORMING CLEAN UP!!! =====")
  wrksp.deleteContents()
  println("ls now " + wrksp.list())
  println("Free space now " + wrksp.getFreeDiskSpace())
}

如果找到工作，其输出如下：

RootDir: /var/lib/jenkins/jobs/Sandbox/jobs/PipelineTests/jobs/SamplePipeline
....
.... other node's output noise
....
Node 'mcs-ubuntu-chch' is online - performing cleanup:
WRKSP /var/lib/jenkins/workspace/Sandbox/PipelineTests/SamplePipeline
ls [/var/lib/jenkins/workspace/Sandbox/PipelineTests/SamplePipeline/README.md, /var/lib/jenkins/workspace/Sandbox/PipelineTests/SamplePipeline/.git]
Free space 3494574714880
===== PERFORMING CLEAN UP!!! =====
ls now []
Free space now 3494574919680

任务完成：）

主要是詹金斯·贾瓦多克

• https://javadoc.jenkins.io/hudson/model/Node.html