Mocked方法在检查调用时也返回null

Question

我不确定我是否滥用了基于交互的测试，或者我是否做了一些概念上的错误。我正在开发一个Spring Boot应用程序(Kotlin)，我的测试使用的是Spock/Groovy。

我有一个正在测试的类，它调用另一个服务来查询信息。被测试的类应该缓存结果。但是，我不能用返回值模拟一个方法并检查调用的次数，因为当我添加调用检查时，被模拟的方法总是返回null。

我创建了一个独立的示例，演示了这个问题。

@Service
class DemoService(private val downstreamService: DownstreamService) {
    fun demo(id: String): String {
        val something = downstreamService.something(id)
        return something
    }
}

@Service
class DownstreamService {
    fun something(id: String): String {
        return id
    }
}

class DemoServiceTest extends Specification {
    def downStream = Mock(DownstreamService)
    def demoService = new DemoService(downStream)

    def "value check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        def actual = demoService.demo(test)

        then:
        actual == "xxx" // works
    }   

    def "invocation check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        demoService.demo(test)

        then:
        1 * downStream.something(test) // works
    }

    def "combined check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        def demo = demoService.demo(test)

        then:
        1 * downStream.something(test)
        demo == "xxx" // fails because demo is null
    }

}

前两个测试按预期工作，但最后一个测试失败了，因为当我添加调用检查时，返回值总是null。

Answer 1

将mock与调用计数检查相结合存在一个问题，因为那时没有调用mock。

def "combined check"() {
    given:
    def test = 'my test string'

    when:
    def demo = demoService.demo(test)

    then:
    1 * downStream.something(test) >> 'xxx'
    demo == 'xxx'
}