错误:未找到自定义方法的Gradle DSL方法

Question

我在构建中添加自定义方法时遇到问题。gradle文件来检索git分支并提交哈希。这是我的密码：

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "***.***.***"
        minSdkVersion 21
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        buildConfigField "String", "GIT_HASH", getGitHash()
        buildConfigField "String", "GIT_BRANCH", getGitBranch()
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    def getGitHash = { ->
        def stdout = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-parse', 'HEAD'
            standardOutput = stdout
        }
        return "\"" + stdout.toString().trim() + "\""
    }

    def getGitBranch = { ->
        def stdout = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-parse', '--abbrev-ref', 'HEAD'
            standardOutput = stdout
        }
        return "\"" + stdout.toString().trim() + "\""
    }
}

问题出在哪里？我得到了以下错误：

BUILD FAILED in 0s
ERROR: Gradle DSL method not found: 'getGitHash()'

我的gradle插件版本是3.5

Answer 1

问题在于getGitHash和getGitBranch方法的定义在构建的android。格雷德尔档案。相反，它们需要位于android部分之上。例如：

def getGitHash = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'rev-parse', 'HEAD'
        standardOutput = stdout
    }
    return "\"" + stdout.toString().trim() + "\""
}

def getGitBranch = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'rev-parse', '--abbrev-ref', 'HEAD'
        standardOutput = stdout
    }
    return "\"" + stdout.toString().trim() + "\""
}

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "***.***.***"
        minSdkVersion 21
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        buildConfigField "String", "GIT_HASH", getGitHash()
        buildConfigField "String", "GIT_BRANCH", getGitBranch()
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

这样做已解决问题

Answer 2

gradle中定义的自定义方法“getGitHash()”只在这个gradle文件中可用。请检查一下你是否是从外面打来的。你还需要在使用方法之前定义它，也就是说，把它放在你的代码上面。