表达式、顺序的OCaml评估？

Question

add是OCaml内置的函数。

经验：

# add 5 1;;
- : int = 6

我的问题：add 3（add 5 3）的求值顺序是什么？

# add 3 (add 5 3);;
- : int = 11

是先将（add 5 3）求值为8，然后将add 3（8）求值为11？还是先将add 3求值为函数，然后将（add 5 3）用作函数（add 3）的参数？

谢谢

Answer 1

OCaml中参数的计算顺序未指定，这意味着它可以从一个编译器更改到另一个编译器。

让我们创建一个分两个阶段评估的函数：

let mul a =
  Printf.printf "got a: %i\n%!" a;
  fun b ->
    Printf.printf "got b: %i\n%!" b;
    a * b

使用utop（或ocaml）运行此操作将显示从右到左的评估：

# mul (mul 2 3) (mul 5 7);;
got a: 5
got b: 7
got a: 2
got b: 3
got a: 6
got b: 35
- : int = 210

可以在中引入let-来强制计算顺序，从而产生不同的printf序列：

# let mul6 = mul (mul 2 3) in mul6 (mul 5 7);;
got a: 2
got b: 3
got a: 6
got a: 5
got b: 7
got b: 35
- : int = 210

Answer 2

为了完成Jeffrey的回答，这里有一个版本的add，可以让你知道它何时被执行：

# let add a b =
    Printf.printf "Adding %d and %d...\n" a b;
    a + b;;

val add : int -> int -> int = <fun>

让我们看看它的实际行动。

# add (add 1 2) (add 5 8);;

Adding 5 and 8...
Adding 1 and 2...
Adding 3 and 13...

- : int = 16

所以在这里，第二个add首先被计算，但是你不能指望它，因为它没有被指定。

下面是使用本地let强制订单的相同示例：

# let x = add 1 2 in
  add x (add 5 8);;

Adding 1 and 2...
Adding 5 and 8...
Adding 3 and 13...

- : int = 16

现在使用部分应用程序。

# let add_3 = add 3 in
  add_3 (add 5 8);;

Adding 5 and 8...
Adding 3 and 13...

- : int = 16

当然，对于（纯）函数式编程，执行顺序并不重要，因为一切都是不变的。但是OCaml并不是纯功能性的，所以这些小技巧是很好了解的。：）

Answer 3

值得一提的是，OCaml中没有内置名为add的函数。（也就是说，渗透模块中没有这样的符号。）

$ ocaml
        OCaml version 4.06.0

# add;;
Error: Unbound value add

OCaml中函数及其参数的求值顺序未指定。所以没有保证的秩序。

OCaml手册第7.7.1节对此进行了记录。

如果你想让一个计算按照一定的顺序进行，你可以使用let来计算每个子表达式：

# let add a b = a + b;;
val add : int -> int -> int = <fun>
# let temp = add 5 3 in
  add 3 temp;;
- : int = 11
# let tempf = add 3 in
  tempf (add 5 3);;
- : int = 11