VBA Class（）对象作为另一个类的属性

Question

我试图创建一个类来保存数量可变的项（它们本身就是另一个类对象）。

我有第二课：

' Class 2 contain each individual quote elements (OTC and MRC)

Private pOTC As String
Private pMRC As String
Public Property Get OTC() As String
    OTC = pOTC
End Property
Public Property Let OTC(Value As String)
    pOTC = Value
End Property

Public Property Get MRC() As String
    MRC = pMRC
End Property
Public Property Let MRC(Value As String)
    pMRC = Value
End Property

然后类1包含类2的数组：

Private pCurr As String
Private pQuote(20) As Class2

Public Property Get Curr() As String
    Curr = pCurr
End Property
Public Property Let Curr(Value As String)
    pCurr = Value
End Property

Public Property Set Quote(Index As Integer, cQuote As Class2)
    Set pQuote(Index) = cQuote
End Property

Public Property Get Quote(Index As Integer) As Class2
    Quote = pQuote(Index)
End Property

我想做的是：

Dim myQuotes As Class1
Set myQuotes = New Class1

myQuotes.Curr = "GBP"
myQuotes.Quote(3).OTC = "1200"  

第一行设置myQuotes。Curr是没有问题的，但是当我试图在数组中设置一个值时，下一行错误与运行时91对象变量或块变量未设置

有没有关于我做错了什么以及如何设置类数组中元素的值的指针？

提前谢谢！

Answer 1

也许应该是这样

Public Property Let Quote(Index As Integer, cQuote As Class2)
    Set pQuote(Index) = cQuote
End Property

Answer 2

您需要将它们设置为Class1中的新Class2：

For intI = LBOUND(pQuote) to UBOUND(pQuote)
    Set pQuote(intI) =  New Class2
Next IntI

就像你在最终脚本中对第一类所做的那样。

Answer 3

当你myQuotes时。Quote（3）您调用属性获取Quote，它有一个问题。

您的内部Class2数组没有实例化，因此pQuote（Index）引用无的数组元素，然后您将myQuote. Quote（3）. OTC=尝试将其分配给无失败。

您需要确保实例化了pQuote（Index）；您可以按需执行此操作：

Public Property Get Quote(Index As Integer) As Class2
   If (pQuote(Index) Is Nothing) Then Set pQuote(Index) = New Class2
   Set Quote = pQuote(Index)
End Property

（注意所需的设置）

或者通过将初始化例程添加到Class1：

Private Sub Class_Initialize()
    Dim Index As Long
    For Index = 0 To UBound(pQuote)
         Set pQuote(Index) = New Class2
    Next
End Sub