如何使用cmake创建共享库？

Question

我已经编写了一个库，过去我使用自编的Makefile编译它，但现在我想切换到cmake。树是这样的（我删除了所有不相关的文件）：

.
├── include
│   ├── animation.h
│   ├── buffers.h
│   ├── ...
│   ├── vertex.h
│   └── world.h
└── src
    ├── animation.cpp
    ├── buffers.cpp
    ├── ...
    ├── vertex.cpp
    └── world.cpp

我只是想把它编译到一个共享的文件库中。

我发现的大多数示例都使用一些共享库编译可执行文件，但绝不仅仅是一个普通的共享库。如果有人能告诉我一个使用cmake的非常简单的库，那也会很有帮助，所以我可以用这个作为例子。

Answer 1

我正在尝试自己学习如何实现这一点，您似乎可以这样安装库：

cmake_minimum_required(VERSION 2.4.0)

project(mycustomlib)

# Find source files
file(GLOB SOURCES src/*.cpp)

# Include header files
include_directories(include)

# Create shared library
add_library(${PROJECT_NAME} SHARED ${SOURCES})

# Install library
install(TARGETS ${PROJECT_NAME} DESTINATION lib/${PROJECT_NAME})

# Install library headers
file(GLOB HEADERS include/*.h)
install(FILES ${HEADERS} DESTINATION include/${PROJECT_NAME})

Answer 2

这是最小的CMakeLists。txt文件编译了一个简单的共享库：

cmake_minimum_required(VERSION 2.8)

project (test)
set(CMAKE_BUILD_TYPE Release)

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
add_library(test SHARED src/test.cpp)

但是，我没有使用CMake将文件复制到其他目的地的经验。带有COPY/INSTALL签名的file命令看起来可能有用。

Answer 3

始终指定cmake的最低要求版本

cmake_minimum_required(VERSION 3.9)

您应该声明一个项目。cmake说它是强制性的，它将定义方便的变量PROJECT_NAME，PROJECT_VERSION和PROJECT_DESCRIPTION（后一个变量需要cmake 3.9）：

project(mylib VERSION 1.0.1 DESCRIPTION "mylib description")

声明一个新的库目标。请避免使用file（GLOB...）。此功能不提供编译过程的参与式掌握。如果您是懒惰的，请复制粘贴输出ls-1 source/*. cpp：

add_library(mylib SHARED
    sources/animation.cpp
    sources/buffers.cpp
    [...]
)

设置VERSION属性（可选，但这是一个良好的做法）：

set_target_properties(mylib PROPERTIES VERSION ${PROJECT_VERSION})

您还可以将SOVERSION设置为VERSION的主要编号。所以libmylib。所以1将是指向libmylib的符号链接。所以1.0.0。

set_target_properties(mylib PROPERTIES SOVERSION 1)

声明库的公共API。此API将为第三方应用程序安装。将其隔离在项目树中是一个很好的做法（如将其放在包括/目录中）。请注意，不应该安装私有头，我强烈建议将它们与源文件放在一起。

set_target_properties(mylib PROPERTIES PUBLIC_HEADER include/mylib.h)

如果您使用子目录，包含像".../包括/mylib. h"这样的相对路径不是很方便。所以，在包含的目录中传递一个顶部目录：

target_include_directories(mylib PRIVATE .)

或者

target_include_directories(mylib PRIVATE include)
target_include_directories(mylib PRIVATE src)

为你的库创建一个安装规则。我建议使用CMAKE_INSTALL_*DIR中定义的变量GNUInstallDir：

include(GNUInstallDirs)

并声明要安装的文件：

install(TARGETS mylib
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

您还可以导出pkg config文件。此文件允许第三方应用程序轻松导入您的库：

• 使用Makefile，请参见pkg-config
• 使用自动工具，请参阅PKG_CHECK_MODULES
• 使用cmake，请参见pkg_check_modules

创建一个名为mylib.pc.in的模板文件（有关详细信息，请参阅pc（5）manpage）：

prefix=@CMAKE_INSTALL_PREFIX@
exec_prefix=@CMAKE_INSTALL_PREFIX@
libdir=${exec_prefix}/@CMAKE_INSTALL_LIBDIR@
includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@

Name: @PROJECT_NAME@
Description: @PROJECT_DESCRIPTION@
Version: @PROJECT_VERSION@

Requires:
Libs: -L${libdir} -lmylib
Cflags: -I${includedir}

在您的CMakeLists.txt中，添加一个扩展@宏的规则（@ONLY要求cmake不扩展表单${VAR}的变量）：

configure_file(mylib.pc.in mylib.pc @ONLY)

最后，安装生成的文件：

install(FILES ${CMAKE_BINARY_DIR}/mylib.pc DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig)

您也可以使用cmakeEXPORT功能。然而，该功能仅与cmake兼容，我发现很难使用。

最后是整个CMakeLists。txt应该是这样的：

cmake_minimum_required(VERSION 3.9)
project(mylib VERSION 1.0.1 DESCRIPTION "mylib description")
include(GNUInstallDirs)
add_library(mylib SHARED src/mylib.c)
set_target_properties(mylib PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION 1
    PUBLIC_HEADER api/mylib.h)
configure_file(mylib.pc.in mylib.pc @ONLY)
target_include_directories(mylib PRIVATE .)
install(TARGETS mylib
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(FILES ${CMAKE_BINARY_DIR}/mylib.pc
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig)

编辑

正如评论中提到的，为了符合标准，您应该能够生成静态库和共享库。这个过程有点复杂，与最初的问题不匹配。但是值得一提的是，这里有很多解释。