Gradle compileJpaModelgenJava失败

Question

> gradle build
:initJpaModelgenSourcesDir
:compileJpaModelgen UP-TO-DATE
:compileJava UP-TO-DATE
:processResources UP-TO-DATE
:classes UP-TO-DATE
:findMainClass
:jar
:bootRepackage
:assemble
:compileJpaModelgenJava

Mapping_.java:3: error: cannot find symbol
import com.<snip>.model.domain.auth.Member;
                                   ^
  symbol:   class Member
  location: package com.<snip>.model.domain.auth
Mapping_.java:7: error: package javax.persistence.metamodel does not exist
import javax.persistence.metamodel.SingularAttribute;
                                  ^
Mapping_.java:8: error: package javax.persistence.metamodel does not exist
import javax.persistence.metamodel.StaticMetamodel;
                                  ^

100 errors
:compileJpaModelgenJava FAILED

FAILURE: Build failed with an exception.

buildscript {
    ext {
        springBootVersion = '1.4.2.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath('gradle.plugin.at.comm_unity.gradle.plugins:jpamodelgen-plugin:1.1.2')
    }
}

plugins {
    id "at.comm_unity.gradle.plugins.jpamodelgen" version "1.1.2"
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'findbugs'
apply plugin: 'jacoco'

jar {
    baseName = 'services'
    version = '1.0.0'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

jpaModelgen {
    library = "org.hibernate:hibernate-jpamodelgen:5.0.11.Final"
    jpaModelgenSourcesDir = "src/generated/java"
}

findbugs {
    ignoreFailures = true
    reportLevel = 'low'
}

javadoc {
    failOnError = false
}

dependencies {
    // Spring Boot, some Apache Commons libs and JDBC Drivers.
}

sourceSets {
    unitTest {
        resources {
            srcDir "resources"
        }
    }
    /*generated {
        java.srcDir "${buildDir}/src/generated/java"
    }*/
}

compileJava.options.compilerArgs += ["-proc:none"]

复仇者集结！我需要帮助，拜托。

Answer 1

我曾希望有人知道这个问题的解决方案，并保留插件，但很明显，没有。我找到了一种不同的方法，不依赖插件，自己做了更多的工作。

我的解决方案就是基于这个答案。

• 已删除插件。
• 编译到Hibernate的jPamodelgen的依赖项。
• 定义了一个变量generatedsourcesdir...
• ...它被添加到主java源代码集。
• 创建了一个自定义删除任务RemoveGeneratedMetamodel，这是必需的，否则将会出现像这样的编译器错误。
• 向生成元模型的compileJava添加了一些选项。
• 添加了对RemoveGeneratedMetamodel到CompileJava和Clean任务的依赖关系。

buildscript {
    ext {
        springBootVersion = '1.4.2.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'findbugs'
apply plugin: 'jacoco'

jar {
    baseName = 'services'
    version = '1.0.0'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

findbugs {
    ignoreFailures = true
    reportLevel = 'low'
}

javadoc {
    failOnError = false
}

dependencies {
    // Spring Boot, some Apache Commons libs and JDBC Drivers.

    compile group: 'org.hibernate', name: 'hibernate-jpamodelgen', version: '5.0.11.Final'
}

ext {
    generatedSourcesDir = file("src/main/java/generated")
}

sourceSets {
    unitTest {
        resources {
            srcDir "resources"
        }
    }
    main {
        java {
            srcDir 'src/main/java'
            srcDir generatedSourcesDir
        }
    }
}

task removeGeneratedMetamodel(type: Delete) {
    generatedSourcesDir.deleteDir()
}

compileJava {
    doFirst {
        generatedSourcesDir.mkdirs()
    }
    dependsOn(removeGeneratedMetamodel)
    options.compilerArgs += ['-s', generatedSourcesDir]
}

clean.dependsOn(removeGeneratedMetamodel)