Jenkins - 无法从 Jenkinsfile 运行管道

Question

我有一个Jenkinsfile，其中构建和测试在同一个Slaver上运行。我的要求是，构建必须在一个从站（比如A）上，测试必须在另一个从站（比如B）上运行。

我刚刚设置了奴隶B，我可以看到我的奴隶A和B都在Jenkins-

以下是看到的问题：

1.)在构建阶段成功后，我得到以下错误:

" java.lang.NoSuchMethodError:在步骤[archive，bat，build，catchError，checkout，deleteDir，Dir，dockerFingerprintFrom，dockerFingerprintRun，dockerNode，echo，emailext，emailextrecipients，envVarsForTool，Error，fileExists，findBuildScans，getContext，git，input，isUnix，junit，library，libraryResource，load，lock，mail，milestone，Node，parallel，powershell，properties，publishHTML antTarget、any、anyOf、apiToken、archiveArtifacts、artifactManager、attach、authorizationMatrix、batchFile、booleanParam、branch、brokenBuildSuspects、brokenTestsSuspects、buildButton、buildDiscarder、buildTimestamp、build timestamp Java . util . concurrent . threadpool executor＄worker . run(threadpool executor . Java at Java . lang . thread . run(thread . Java:748)Finished:FAILURE "

2.）没有看到我的分支的“准备测试”和“测试”阶段，但我可以看到与构建相关的阶段。

附上我的Jenkins文件代码：

pipeline {
    agent none
    options {
        skipDefaultCheckout true
    }
    stages {
        stage('build') {
            agent {
                docker {
                    image 'XYZ'
                    args '-v /etc/localtime:/etc/localtime:ro'
                }
            }
            options { skipDefaultCheckout(true) }
            steps {
                echo '########################################## Building #########################################'
                // trigger the build
                sh 'scm-src/build.sh all-projects'
            }
        }   

   }
} 


pipeline {
    agent {
        label 'laptop-hp'
    }
    stages {
        stage('prepare_test') {
              agent {
                 docker {
                    image 'ABC'
                    args '-v /home/jenkins/.ssh/:/home/jenkins/.ssh:ro -v /etc/localtime:/etc/localtime:ro'
                }
               }
            options { skipDefaultCheckout(true) }
            steps {
                echo '####################################### Prepare Test Environment ############################'
                sh 'scm-src/test.sh prepare'
            }
         }


        stage('test') {
            agent {
              docker {
                     image 'ABC'
                     args '-v /home/jenkins/.ssh/:/home/jenkins/.ssh:ro -v /etc/localtime:/etc/localtime:ro'
                 }
               }

            options { skipDefaultCheckout(true) }
            steps {
               echo '########################################## Testing ##########################################'
                sh 'scm-src/test.sh run'
            }
        }
    }  
}

在Jenkinsfile中，我的从属服务器B的名称是“laptop-hp”

Jenkinsfile有问题吗？还是我错过了从机B上的一些设置？

关于kdy

Answer 1

在一个声明性管道中，您不能有多个管道{}块。正确的语法是在构建阶段之后立即附加您的测试阶段。然后为docker{}中的每个阶段定义参数标签以在相应的从站上运行。此外，在管道的顶层添加一次选项skipDefaultCheckout true就足够了。

您的管道现在应如下所示：

pipeline {
    agent none
    options {
        skipDefaultCheckout true
    }
    stages {
        stage('build') {
            agent {
                docker {
                    image 'XYZ'
                    label 'slave-A'
                    args '-v /etc/localtime:/etc/localtime:ro'
                }
            }
            steps {
                echo '########################################## Building #########################################'
                // trigger the build
                sh 'scm-src/build.sh all-projects'
            }
        }   
        stage('prepare_test') {
            agent {
                docker {
                    image 'ABC'
                    label 'laptop-hp'
                    args '-v /home/jenkins/.ssh/:/home/jenkins/.ssh:ro -v /etc/localtime:/etc/localtime:ro'
                }
            }
            steps {
                echo '####################################### Prepare Test Environment ############################'
                sh 'scm-src/test.sh prepare'
            }
        }
        stage('test') {
            agent {
                docker {
                    image 'ABC'
                    label 'laptop-hp'
                    args '-v /home/jenkins/.ssh/:/home/jenkins/.ssh:ro -v /etc/localtime:/etc/localtime:ro'
                }
            }
            steps {
                echo '########################################## Testing ##########################################'
                sh 'scm-src/test.sh run'
            }
        }
    }
}