为什么“Julia Language Documentation”中的这一行为输入参数是不同类型的情况定义了一个外部构造函数？

Question

为了构建性能良好的队列应用程序，我正在重读Julia语言文档，关于参数构造函数和外部构造函数的部分让我感到困惑。它们展示的例子如下：

julia> struct OurRational{T<:Integer} <: Real
           num::T
           den::T
           function OurRational{T}(num::T, den::T) where T<:Integer
               if num == 0 && den == 0
                    error("invalid rational: 0//0")
               end
               g = gcd(den, num)
               num = div(num, g)
               den = div(den, g)
               new(num, den)
           end
       end

julia> OurRational(n::T, d::T) where {T<:Integer} = OurRational{T}(n,d)
OurRational

julia> OurRational(n::Integer, d::Integer) = OurRational(promote(n,d)...)
OurRational

julia> OurRational(n::Integer) = OurRational(n,one(n))
OurRational

文件指出：

第一个是“标准”的一般（外部）构造函数，当分子和分母具有相同的类型时，它从它们的类型推断类型参数T。

由此我开始理解这个构造函数处理两个参数的情况。它从（num和den）的类型中推断出T，然后将其提供给OurRational内部构造函数。

文件接着说：

第二种方法适用于给定的分子和分母值具有不同类型时：它将它们提升为公共类型，然后将构造委托给外部构造函数以获取匹配类型的参数。

看着代码，我不明白这是怎么回事。根据我认为Julia是如何计算的，第二个构造函数难道不会处理n和d都是显式整数的情况吗？如果不是这样的话，我真的很难看到朱莉娅是如何看待这条线的。另外，赋值后缀中的省略号意味着“现在，当两个参数具有相同类型时，转到外部构造函数”，对吗？

我很好地理解第三个外部构造函数。

Answer 1

第一个和第二个外部构造函数不同，因为第二个构造函数处理的情况是分子和命名都是整数，但却是两个不同的具体子类型，都是抽象类型Integer。

正如您所知，Julia有许多builtin整数类型。例如，考虑UInt8，它是单字节语法的默认类型，如0x1F。看看将UInt8和默认整数类型INT64混合后的结果：

julia> struct OurRational{T<:Integer} <: Real
           num::T
           den::T
           function OurRational{T}(num::T, den::T) where T<:Integer
               println("Inner")
               if num == 0 && den == 0
                   error("invalid rational: 0//0")
               end
               g = gcd(den, num)
               num = div(num, g)
               den = div(den, g)
               new(num, den)
           end
       end

julia>

julia> OurRational(n::T, d::T) where {T<:Integer} = begin println("Outer 1"); OurRational{T}(n,d) end
OurRational

julia> OurRational(n::Integer, d::Integer) = begin println("Outer 2"); OurRational(promote(n,d)...) end
OurRational

julia> OurRational(n::Integer) = begin println("Outer 3"); OurRational(n,one(n)) end
OurRational

julia> OurRational{UInt8}(0x2, 0x5)
Inner
OurRational{UInt8}(0x02, 0x05)

julia> OurRational(2, 5)
Outer 1
Inner
OurRational{Int64}(2, 5)

julia> OurRational(0x2, 5)
Outer 2
Outer 1
Inner
OurRational{Int64}(2, 5)

julia> OurRational(0x3)
Outer 3
Outer 1
Inner
OurRational{UInt8}(0x03, 0x01)

因此，第二个外部构造函数将参数提升为相同的类型，然后将它们传递给第一个外部构造函数，然后将其传递给内部构造函数。