Spock模拟在collabolator内部返回null，但在feature方法中不返回null

Question

我对Spock Mock（）对象有一个问题。我有一个java类正在尝试测试。这个类做了一些我想模拟的ftp内容。我的示例代码

class ReceiveDataTest extends Specification{
    String downloadPath = 'downloadPath';
    String downloadRegex = 'downloadRegex';
    SftpUtils sftpUtils = Mock();
    ReceiveData receiveData;

    def setup(){
        sftpUtils.getFileNames(downloadPath,downloadRegex) >> ['file1', 'file2']
        receiveData= new ReceiveData()
        receiveData.setDownloadPath(downloadPath)
        receiveData.setDownloadRegex(downloadRegex)
        receiveData.setSftpUtils(sftpUtils);

    }

    def "test execute"() {
        given:
        def files = sftpUtils.getFileNames(downloadPath,downloadRegex)
        files.each{println it}
        when:
        receiveData.execute();
        then:
        1*sftpUtils.getFileNames(downloadPath,downloadRegex)
    }

}

public class ReceiveData(){

  //fields, setters etc

    public void execute() {
        List<String> fileNames = sftpUtils.getFileNames(downloadPath, downloadRegex);

        for (String name : fileNames) {
            //dowload and process logic
        }

    }
}

现在，在“test execute”中的文件。each{}打印预期的内容。但当调用receivedata.execute（）时，我的sftpUtils返回null。知道为什么吗？

Mockito.when(sftpUtils.getFilenames(downloadPath, downloadRegex)).thenReturn(filenamesList);
receiveData.execute();

Mockito.verify(sftpUtils).getFilenames(downloadPath, downloadRegex);
//this is what I want to test and resides inside for loop
Mockito.verify(sftpUtils).download(downloadPath, filenamesList.get(0));
Mockito.verify(sftpUtils).delete(downloadPath, filenamesList.get(0));

Answer 1

主要的问题是您没有将响应生成器(>>部分）包含在期望中（即then：块中的“1*...”部分）。

这在spock文档中有很好的解释。

>

http://spockframework.org/spock/docs/1.0/interaction_based_testing.html#_combining_mocking_and_stubing

您不必在setup：块中声明存根。您只需要在then：块中指定它一次--即使这是在调用receivedata.execute（）之后。由于Groovy AST转换，这就是spock的部分魔力。而且由于（非共享的）字段在每次测试之前都被重新初始化（更多的是基于AST的魔术），在这种情况下甚至不需要setup（）。

另一件奇怪的事情是，您既删除了sftputils.getFileNames()，又从测试代码中调用了它。模拟和存根用于替换从测试中的系统调用的协作器。没有理由调用测试驱动程序的存根。因此，从给定块中删除对getFilenames（）的调用，并让测试中的代码调用它（正如它所做的那样）。

Groovy允许您简化对Java set和get方法的调用。看看下面receiveData的初始化。在Groovy中使用def是可以的。让编译器为您计算出数据类型。

导致类似于：

class ReceiveDataTest extends Specification {

    // only use static for constants with spock
    static String PATH = 'downloadPath'
    static String REGEX = 'downloadRegex'

    def mockSftpUtils = Mock(SftpUtils)

    def receiveData = new ReceiveData(downloadPath : PATH,
                                      downloadRegex : REGEX,
                                      sftpUtils : mockSftpUtils)

    def "execute() calls getFileNames() exactly once"() {
       when:
           receiveData.execute()
       then:
            1 * mockSftpUtils.getFileNames(PATH, REGEX) >> ['file1', 'file2']
            0 * mockSftpUtils.getFileNames(_,_) 

           // The second line asserts that getFileNames() is never called
           // with any arguments other than PATH and REGEX, aka strict mocking
           // Order matters! If you swap the lines, the more specific rule would never match
    }
}