ANTLR4:使用单独语法时出现grun错误（ClassCastException）

Question

我试图创建一种自定义语言，将lexer规则与parser规则分开。此外，我的目标是进一步将lexer和parser规则划分到特定的文件中（例如，通用lexer规则和关键字规则）。

但我似乎无法让它发挥作用。

1. // MyLang.g4
   parser grammar MyLang;
   
   options { tokenVocab = MyLangL; }
   
   prog
       : ( func )* END
       ;
   
   func
       : DIR ID L_BRKT  (stat)* R_BRKT
       ;
   
   stat
       : expr SEMICOLON
       | ID OP_ASSIGN expr SEMICOLON
       | SEMICOLON
       ;
   
   expr
       : expr OPERATOR expr
       | NUMBER
       | ID
       | L_PAREN expr R_PAREN
       ;
   

   // MyLangL.g4
   lexer grammar MyLangL;
   
   import SkipWhitespaceL, CommonL, KeywordL;
   
   @header {
   package com.invensense.wiggler.lexer;
   }
   
   @lexer::members {   // place this class member only in lexer
   Map<String,Integer> keywords = new HashMap<String,Integer>() {{
       put("for",          MyLangL.KW_FOR);
       /* add more keywords here */
   }};
   }
   
   ID  :   [a-zA-Z]+
           {
           if ( keywords.containsKey(getText()) ) {
               setType(keywords.get(getText())); // reset token type
           }
           }
       ;
   
   DIR
       : 'in'
       | 'out'
       ;
   
   END : 'end' ;
   

   // KeywordL.g4
   lexer grammar KeywordL;
   
   @lexer::header {    // place this header action only in lexer, not the parser
   import java.util.*;
   }
   
   // explicitly define keyword token types to avoid implicit def warnings
   tokens {
       KW_FOR
       /* add more keywords here */
   }
   

   // CommonL.g4
   lexer grammar CommonL;
   
   NUMBER
       : FLOAT
       | INT
       | UINT
       ;
   
   FLOAT
       : NEG? DIGIT+ '.' DIGIT+ EXP?
       | INT
       ;
   
   INT
       : NEG? UINT+
       ;
   
   UINT
       : DIGIT+ EXP?
       ;
   
   OPERATOR
       : OP_ASSIGN
       | OP_ADD
       | OP_SUB
       ;
   
   OP_ASSIGN   : ':=';
   OP_ADD      : POS;
   OP_SUB      : NEG;
   
   L_BRKT          : '[' ;
   R_BRKT          : ']' ;
   L_PAREN         : '(' ;
   R_PAREN         : ')' ;
   SEMICOLON       : ';' ;
   
   fragment EXP
       : [Ee] SIGN? DIGIT+
       ;
   
   fragment SIGN
       : POS
       | NEG
       ;
   
   fragment POS: '+' ;
   fragment NEG : '-' ;
   fragment DIGIT : [0-9];
   

   // SkipWhitespaceL.g4
   lexer grammar SkipWhitespaceL;
   
   WS
       :   [ \t\r\n]+ -> channel(HIDDEN)
       ;
   

   ussjc-dd9vkc2 | C:\M\w\s\a\l\example
   § antlr4.bat .\MyLangL.g4
   
   ussjc-dd9vkc2 | C:\M\w\s\a\l\example
   § antlr4.bat .\MyLang.g4
   
   ussjc-dd9vkc2 | C:\M\w\s\a\l\example
   § javac *.java
   
   ussjc-dd9vkc2 | C:\M\w\s\a\l\example
   § grun MyLang prog -tree
   Exception in thread "main" java.lang.ClassCastException: class MyLang
           at java.lang.Class.asSubclass(Unknown Source)
           at org.antlr.v4.gui.TestRig.process(TestRig.java:135)
           at org.antlr.v4.gui.TestRig.main(TestRig.java:119)
   
   ussjc-dd9vkc2 | C:\M\w\s\a\l\example
   §
   

Answer 1

使用MyLangParser和MyLangLexer重命名文件，然后运行grun MyLang prog-tree