Android上的Delphi FireMonkey TListBox

Question

在Delphi 10.0 Seattle中，我在向FireMonkeyTListBox添加Tobject值时遇到问题。

将integer变量强制转换为tobject指针时会引发exeception。

下面是我的代码：

var
  jValue:TJSONValue;
  i,total,id: integer;
  date: string;
begin
  while (i < total) do
  begin
    date := converteDate(jValue.GetValue('date' + IntToStr(i), ''));
    id := StrToInt(jValue.GetValue('id' + IntToStr(i), ''));
    ListBox1.Items.AddObject(date, TObject(id));
    i := i + 1;
  end;
end;

Answer 1

问题是，在iOS和Android（以及不久的Linux）上，tobject使用自动引用计数进行生存期管理，因此，您不能像在不使用ARC的Windows和OSX上那样将整数值类型转换为tobject指针。在ARC系统上，tobject指针必须指向真实对象，因为编译器要对它们执行引用计数语义。这就是为什么你会得到一个例外。

为了完成您正在尝试的操作，您必须在ARC系统中将整数值包装在真实对象中，例如：

{$IFDEF AUTOREFCOUNT}
type
  TIntegerWrapper = class
  public
    Value: Integer;
    constructor Create(AValue: Integer);
  end;

constructor TIntegerWrapper.Create(AValue: Integer);
begin
  inherited Create;
  Value := AValue;
end;
{$ENDIF}

...

ListBox1.Items.AddObject(date, {$IFDEF AUTOREFCOUNT}TIntegerWrapper.Create(id){$ELSE}TObject(id){$ENDIF});

...

{$IFDEF AUTOREFCOUNT}
id := TIntegerWrapper(ListBox1.Items.Objects[index]).Value;
{$ELSE}
id := Integer(ListBox1.Items.Objects[index]);
{$ENDIF}

否则，将整数存储在单独的列表中，然后在需要时使用TListBox项的索引作为该列表的索引，例如：

uses
  .., System.Generics.Collections;

private
  IDs: TList<Integer>;

...

var
  ...
  Index: Integer;
begin    
  ...
  Index := IDs.Add(id);
  try
    ListBox1.Items.Add(date);
  except
    IDs.Delete(Index);
    raise;
  end;
  ...
end;

...

Index := ListBox1.Items.IndexOf('some string');
id := IDs[Index];

这可以移植到所有平台，而不必使用ifdefs或担心ARC。