Gradle 4.8+使用自定义配置打破了ivy publish

Question

我有一个gradle文件，它在gradle的一些古老版本中工作，但我想升级到Gradle5.0。不幸的是，它使用了ivy而不是maven来发布它的JAR。我把它简化为一个简单的测试用例。

./gradlew wrapper && ./gradlew publish --info && cat build/publications/ivy/ivy.xml

• 在4.7中可以正常工作。它发布主jar和源jar，并添加依赖项。
• 如果切换到4.8，它会中断，它只发布源jar，主jar和依赖项都丢失了。
• 如果切换到4.8并注释掉配置位，它将再次发布主jar和依赖项。

也许有一种新的做事方式，但如果是这样的话，我没有找到它的文档。这是原始建筑。格拉德尔。

plugins {
  id 'java'
  id 'ivy-publish'
}   

sourceSets {
  testSupport {
    java {
      compileClasspath += main.output
      runtimeClasspath += main.output
    }
  }
  test {
    java {
      compileClasspath += testSupport.output
      runtimeClasspath += testSupport.output
    }
  }
}

dependencies {
  compile group: 'com.ibm.icu', name: 'icu4j', version: '58.2'
  compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.3'
  compile group: 'io.swagger', name: 'swagger-parser', version: '1.0.32'
}

task sourceJar(type: Jar) {
  from sourceSets.main.allJava
}

task testSupportJar(type: Jar) {
  from sourceSets.testSupport.output
  appendix "test-support"
}

task testSupportSourceJar(type: Jar) {
  from sourceSets.testSupport.java.srcDirs
  appendix "test-support-sources"
}
artifacts {
  archives sourceJar
  archives testSupportJar
  archives testSupportSourceJar
}
publishing {
  repositories {
    ivy {
      name = 'myRepo'
      url = "file://${buildDir}/repo"
      layout "pattern", {
        artifact "[organisation]/[module]/[revision]/jars/[artifact].[ext]"
        ivy "[organisation]/[module]/[revision]/ivys/ivy-[revision].xml"
      }
    }
  }
  publications {
    ivy(IvyPublication) {
      organisation = 'com.example.com'
      // If you comment out the configurations below it will generate sensible ivy.xml
      configurations {
        "compile" {}
        "runtime" {}
      } 


      from components.java
      artifact(sourceJar) {
        type "source"
        extension "src.jar"
        conf "runtime"
      }
    }
  }
}

wrapper {
  // 4.7 works but 4.8+ doesn't.
  gradleVersion = '4.7'
}

Answer 1

哦，伙计，我刚刚想通了。它是components.java中的和configurations元素位的相对顺序。如果configurations是第一个，那么它似乎会优先于components.java中的，而后者似乎会被忽略。如果您将components.java中的放在configurations之前，那么它就可以工作，并且您不必再手动声明默认情况下它生成的配置。

弗夫斯·格雷德尔。