要使用哪个处理库来创建同时运行的渲染

Question

我最近在处理(http://processing.org/)我希望知道是否有一个库可以帮助我创建两个不同的窗口来渲染同一场景的两个视图。还有什么方法可以直接从一个切换到另一个。

Answer 1

下面是一个简单的例子：

import java.awt.Graphics;
import java.awt.image.BufferedImage;
import javax.swing.*;

ImagePanel view2;
PImage viewport2 = new PImage(400,400,RGB);

void setup(){
  size(800,400,P3D);
  noStroke();

  frame.setSize(400,400);
  frame.setTitle("view 1");

  view2 = new ImagePanel((BufferedImage)viewport2.getNative());
  JFrame v2 = new JFrame("view 2");
  v2.setSize(400,400);
  v2.add(view2);
  v2.show();
}
void draw(){
  background(0);
  lights();
  //view1
  pushMatrix();
    translate(200,200,0);
    rotateX(45);
    rotateY(map(mouseX,0,height,-PI,PI));
    renderScene();
  popMatrix();
  //view2
  pushMatrix();
  translate(600,200,0);
  rotateY(45);
  rotateX(map(mouseX,0,height,-PI,PI));
  renderScene();
  popMatrix();
  viewport2 = get(400,0,400,400);//fetch a screenshot from the invisible side (right side);
  view2.setImage((BufferedImage)viewport2.getNative());
}
void renderScene(){
  pushMatrix();
  box(100);//and other elements here
  popMatrix();
}

public class ImagePanel extends JPanel{

    private BufferedImage image;

    public ImagePanel(BufferedImage img) {
       setImage(img);
    }
    public void setImage(BufferedImage img){
      image = img;
      this.repaint();
    }
    @Override
    protected void paintComponent(Graphics g) {
        super.paintComponent(g);
        g.drawImage(image, 0, 0, null);        
    }

}

有三件事要看：

1. 生成单独的视图——请注意，草图大小实际上是原来的两倍，我使用push/pop调用隔离变换并渲染相同的数据。也可以随意使用camera（）和perspective（）功能
2. 生成帧。注意，处理使用java语言。awt。使用Frame调整大小的框架。setSize（），我扩展了一个JPanel，以便可以在图形对象中绘制
3. 更新图像：我正在使用get（x，y，width，height）在绘制/渲染循环结束时获取渲染场景的快照。PImage提供了一个getNative（）方法，该方法返回一个BuffereImage表示。这可以被绘制成java。awt。图形实例。我告诉自定义JPanel组件重新绘制以更新像素

这种方法有点奇怪，但是您使用的是具有相同变量的相同草图，而不是两个PApplet实例。

Answer 2

我不知道这样的库是否存在的处理，但你可以很容易地创建两个窗口使用以下代码基于最近的处理论坛线程

import java.awt.Frame;
import java.awt.MouseInfo;
import java.awt.Point;
PFrame f;
secondApplet s;

void setup () {
  size(500, 500);
  PFrame f = new PFrame();
  frame.setTitle("first window");
}


void draw () {
  background(255);
  s.background(0); // Second window background method

// .... //

}

public class PFrame extends Frame {
  public PFrame() {
    setBounds(0, 0, 500, 500);
    s = new secondApplet();
    setResizable(false);
    add(s); 
    s.init(); 
    show();
    setTitle("second window");
  }
}

public class secondApplet extends PApplet {
  public void setup() {
    size(500, 500);
  }
  public void draw() {
  }
}

然后，可以在每个窗口中基于公共数据源和方法创建一个图形。我不是专家，但我希望这能帮助你开始你的项目。

请注意，G4P等GUI库也支持创建多个窗口。

编辑：注释相关代码：

//...//
int x=50;
void draw () {
rect(width/2,0,x,x);
s.rect(s.width/2,0,x+10,x+10);
}
//...//