时髦编译时 AST 转换：对字段的赋值

Question

我目前正在尝试实现一些Groovy编译时AST转换，但遇到了麻烦：

如何为字段的赋值语句指定AST转换？i、 e.AST转换应转换以下代码：

class MyClass {
    @MyTransformation
    String myField

    public void init() {
    }
}

变成类似的东西

class MyClass {
    String myField

    public void init() {
        this.myField = "initialized!"
    }
}

我用这个AST构建器调用进行了尝试：

def ast = new AstBuilder().buildFromSpec {
        expression{
            declaration {
                variable "myField"
                token "="
                constant "initialized!"
            }
        }
}

但在声明类的“init”方法中插入结果语句后，它反而插入了一个变量赋值，如

java.lang.Object myField = "initialized!"

我浏览了Ast Builder TestCase中包含的示例，但它们只涵盖了类主体中的字段声明，而不是字段分配。我自己使用field dNode的尝试都导致了编译器错误。我将编译阶段设置为INSTRUCTION_SELECTION；我认为这应该没问题。

我如何做到这一点？首选基于AstBuilder#buildFromSpec方法的解决方案，但如有任何帮助，我们将不胜感激。

Answer 1

我通常建议不要使用AST构建器。它有利于原型设计，但你并不能真正控制它生成的内容。特别是，在这里，它无法处理您创建的变量表达式应引用字段节点的事实。AST生成器非常适合了解AST，但恕我直言，不应该在生产代码中使用。

这是一个自给自足的例子，展示了你如何实现你想要的。@ASTTest中的代码将与您的转换代码相对应：

import groovy.transform.ASTTest                                                         
import org.codehaus.groovy.ast.expr.BinaryExpression                            
import org.codehaus.groovy.ast.expr.VariableExpression                          
import org.codehaus.groovy.ast.expr.ConstantExpression                          
import org.codehaus.groovy.ast.stmt.ExpressionStatement                         
import org.codehaus.groovy.syntax.Token                                         
import org.codehaus.groovy.syntax.Types      

class MyClass {                                                                         
    String myField                                                                      

    @ASTTest(phase=SEMANTIC_ANALYSIS,value={                                            
            def classNode = node.declaringClass                                         
            def field = classNode.getDeclaredField('myField')                           
            def assignment = new BinaryExpression(                                      
              new VariableExpression(field),                                              
              Token.newSymbol(Types.EQUAL, 0, 0),                                         
              new ConstantExpression('initialized!')                                      
            )                                                                                   
            node.code.addStatement(new ExpressionStatement(assignment))                 
    })                                                                          
    public void init() {                                                                
    }                                                                                   
}                                                                                       
def c = new MyClass()                                                                   
c.init()                                                                                
println c.myField

希望这有帮助！