无法解析Mime消息

Question

Return-Path: <[e-mail]>
X-Original-To: [e-mail]
Delivered-To: [e-mail]
Received: from localhost [127.0.0.1]
    by unify-prod with POP3 (fetchmail-6.3.21)
    for <other@localhost> (single-drop); Mon, 03 Aug 2015 12:42:24+0000 (UTC)
Received: from testdomain.com (testdomain.com [192.69.176.183])
    by unify.test.com (Postfix) with ESMTPS id AA3874330B
    for <[e-mail]>; Mon,  3 Aug 2015 12:42:23 +0000 (UTC)
 Received: from test.call (test.call [10.3.1.49])
    by test.com (Postfix) with ESMTP id 56EC73BA8C4
    for <[e-mail]>; Mon,  3 Aug 2015 12:42:23 +0000 (UTC)
Date: Mon, 3 Aug 2015 12:42:23 +0000 (UTC)
From: [e-mail]
To: [e-mail]
Message-ID: <385098705.398991.1438605743348.JavaMail.sd@sdapp04>
Subject: Update
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 7bit



|0004625641|
|630805367|
|NA14220388|
|03.08.2015 14:42:23|


||

InputStream mailFileInputStream = new FileInputStream("/home/peter/test.msg");
    Properties props = new Properties();
    Session session = Session.getDefaultInstance(props, null);
    MimeMessage message = new MimeMessage(session, mailFileInputStream);

    MimeMessageParser parser = new MimeMessageParser(message)
    parser.parse()


    def data = [:]
    data.from = parser.getFrom()
    data.to = parser.getTo()
    data.replyTo = parser.getReplyTo()
    data.html = parser.getHtmlContent()
    data.plain = parser.getPlainContent()
    data.subject = parser.getSubject()
    data.attachments = parser.getAttachmentList()

向你问好，彼得

Answer 1

当我试图解析消息时，我得到了这个异常：

java.lang.ClassCastException: javax.mail.util.SharedByteArrayInputStream cannot be cast to java.lang.String
    at org.apache.commons.mail.util.MimeMessageParser.parse(MimeMessageParser.java:181)
    at org.apache.commons.mail.util.MimeMessageParser.parse(MimeMessageParser.java:96)
    at org.apache.commons.mail.util.MimeMessageParser$parse.call(Unknown Source)

问题是MimeMessageParser试图将对象强制转换为字符串。您可以在第181行的源代码中看到这一点。该对象是javax.mail.util.SharedByteArrayInputStream的实例，它不会通过强制返回内容。我的示例使用StringBufferInputStream作为输入，因此这可能是问题的一部分。

为了解决这个问题，我重写了mimeMessage.getContent()，以便它返回纯文本内容。所以很明显，不要对非纯文本内容这样做。以下是完整的脚本：

@Grab('org.apache.commons:commons-email:1.4')

import javax.mail.Session
import javax.mail.internet.MimeMessage
import org.apache.commons.mail.util.MimeMessageParser

def input = '''Return-Path: <[e-mail]>
X-Original-To: [e-mail]
Delivered-To: [e-mail]
Received: from localhost [127.0.0.1]
    by unify-prod with POP3 (fetchmail-6.3.21)
    for <other@localhost> (single-drop); Mon, 03 Aug 2015 12:42:24+0000 (UTC)
Received: from testdomain.com (testdomain.com [192.69.176.183])
    by unify.test.com (Postfix) with ESMTPS id AA3874330B
    for <[e-mail]>; Mon,  3 Aug 2015 12:42:23 +0000 (UTC)
 Received: from test.call (test.call [10.3.1.49])
    by test.com (Postfix) with ESMTP id 56EC73BA8C4
    for <[e-mail]>; Mon,  3 Aug 2015 12:42:23 +0000 (UTC)
Date: Mon, 3 Aug 2015 12:42:23 +0000 (UTC)
From: [e-mail]
To: [e-mail]
Message-ID: <385098705.398991.1438605743348.JavaMail.sd@sdapp04>
Subject: Update
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 7bit



|0004625641|
|630805367|
|NA14220388|
|03.08.2015 14:42:23|


||'''

// Creates a MimeMessage that makes MimeMessageParser happy.
MimeMessage createMimeMessage(InputStream stream) {
    def getContent = MimeMessage.metaClass.getMetaMethod('getContent')
    def message = new MimeMessage(
        Session.getDefaultInstance(new Properties()), 
        stream)

    /*
     * Override MimeMessage.getContent()
     * to coerce SharedByteArrayInputStream
     * into a String. Groovy does it automatically :)
     */
    message.metaClass.getContent = {
        getContent.invoke(delegate)
    }

    return message
}

def message = createMimeMessage(new StringBufferInputStream(input))
def parser = new MimeMessageParser(message)

parser.parse()

def data = parser.with {
    [
        from: from,
        to: to,
        replyTo: replyTo,
        html: htmlContent,
        plain: plainContent,
        subject: subject,
        attachments: attachmentList,
    ]
}

assert data.from == '[e-mail]'
assert data.to instanceof List
assert data.replyTo == '[e-mail]'
assert data.html == null
assert data.attachments == []
assert data.plain instanceof String

[from:[e-mail], to:[[e-mail]], replyTo:[e-mail], html:null, plain:

|0004625641|
|630805367|
|NA14220388|
|03.08.2015 14:42:23|


||, subject:Update, attachments:[]]