如何编写可定制的语法？

Question

对于我正在编写的聊天机器人，我想让它的解析器可定制，这样人们就不需要修改机器人本身来为他们想要的任何类型的聊天消息添加钩子。解析器使用语法。目前，我用一个类似这样的类来处理这个问题：

class Rule {
    has Regex:D $.matcher is required;
    has         &.parser  is required;

    method new(::?CLASS:_: Regex:D $matcher, &parser) {
        self.bless: :$matcher, :&parser
    }

    method match(::?CLASS:D: Str:D $target --> Replier:_) {
        $target ~~ $!matcher;
        $/.defined ?? &!parser(self, $/) !! Nil
    }
}

然后，将从解析器的actions类中循环一个数组。这允许人们为解析器添加他们自己的“规则”，这解决了我的问题，但这是笨拙的，这是重新发明语法！我真正想要的是人们能够为我的解析器写一些类似俚语的东西。虽然augment可以用于此，但在这种情况下它没有用处，因为用户可能希望在运行时更改如何扩充解析器，但augment在编译时处理。如何做到这一点？

Answer 1

这需要5行或10行样板，这取决于是否使用actions类。

在撰写本文时，如果您查看一下Metamodel:：GrammarHOW，您会发现：

class Perl6::Metamodel::GrammarHOW
    is Perl6::Metamodel::ClassHOW
    does Perl6::Metamodel::DefaultParent
{
}

语法是类的延伸！这意味着可以在其中声明元方法。在Perl 6中如何使类参数化的基础上构建？，如果用户为grammar和actions类提供角色，则可以在通过参数化进行解析之前将它们混合在一起。如果你以前写过俚语，这听起来可能很熟悉；混合在这样的角色中是$*LANG.refine\u俚语的工作原理！

如果您希望语法中的令牌是可扩充的，那么可以将其设置为原型令牌。之后所需要的只是一个参数化元方法，它将混合在参数中，这将是某种角色：

grammar Foo::Grammar {
    token TOP { <foo> }

    proto token foo          {*}
          token foo:sym<foo> { <sym> }

    method ^parameterize(Foo::Grammar:U $this is raw, Mu $grammar-role is raw --> Foo::Grammar:U) {
        my Foo::Grammar:U $mixin := $this.^mixin: $grammar-role;
        $mixin.^set_name: $this.^name ~ '[' ~ $grammar-role.^name ~ ']';
        $mixin
    }
}

class Foo::Actions {
    method TOP($/) { make $<foo>.made; }

    method foo:sym<foo>($/) { make ~$<sym>; }

    method ^parameterize(Foo::Actions:U $this is raw, Mu $actions-role is raw --> Foo::Actions:U) {
        my Foo::Actions:U $mixin := $this.^mixin: $actions-role;
        $mixin.^set_name: $this.^name ~ '[' ~ $actions-role.^name ~ ']';
        $mixin
    }
}

然后可以这样声明要混合的角色：

role Bar::Grammar {
    token foo:sym<bar> { <sym> }
}

role Bar::Actions {
    method foo:sym<bar>($/) { make ~$<sym>; }
}

现在，如果需要，可以在解析之前使用Bar对Foo进行扩充：

Foo::Grammar.subparse: 'foo', actions => Foo::Actions.new;
say $/ && $/.made; # OUTPUT: foo
Foo::Grammar.subparse: 'bar', actions => Foo::Actions.new;
say $/ && $/.made; # OUTPUT: #<failed match>

Foo::Grammar[Bar::Grammar].subparse: 'foo', actions => Foo::Actions[Bar::Actions].new;
say $/ && $/.made; # OUTPUT: foo
Foo::Grammar[Bar::Grammar].subparse: 'bar', actions => Foo::Actions[Bar::Actions].new;
say $/ && $/.made; # OUTPUT: bar

编辑：元方法可以接受任意数量的角色作为参数，参数化可以使用任何签名。这意味着，如果您稍微调整参数化元方法，您可以使语法或操作类的参数化接受任意数量的角色：

method ^parameterize(Mu $this is raw, *@roles --> Mu) {
    my Mu $mixin := $this.^mixin: |@roles;
    $mixin.^set_name: $this.^name ~ '[' ~ @roles.map(*.^name).join(', ') ~ ']';
    $mixin
}