无法使用线程将数据插入到带有DBIish的PostgreSQL中。出什么问题了？

Question

编辑：莫里茨解决了这个问题。我在代码的行中添加了一个错误的注释。

我的应用程序是一个与游戏客户端对话的网络服务器。服务器是多线程的，Postgres允许。当将客户端数据加载到数据库中时，我注意到并行请求失败，出现了几个不同的错误，这些错误对我来说都没有意义。

这个简短的测试用例将嵌套哈希转储到数据库中。当在没有start的情况下运行时，它可以完美地工作。当使用线程运行时，它几乎总是给出以下一个或多个错误：

DBDish::Pg：错误：（7）在方法准备在D：\rakudo\share\perl6\site\Source\BAD7C1548F63C7AA7BC86BEDDA0F7BD185E141AD（DBDish::Pg::Connection）第48行在testcase. p6的块中第62行
在testcase. p6的子add-enum-mappings中第59行在testcase. p6第91行

DBDish:：Pg:Error:Error:prepared语句“Pg_3448_16”已存在于testcase块中的方法prepare的D:\rakudo\share\perl6\site\sources\BAD7C1548F63C7AA7BC86BEDDA0F7BD185E141AD（DBDish:：Pg:：Connection）第46行。p6第62行
在测试用例中添加枚举映射。p6测试用例块中的第59行。p6第91行

DBDish::Pg：错误：方法执行的参数数错误：在D：\rakudo\share\perl6\site\Source\65FFB78EFA30486D1C4D339882A410E3C94AD2（DBDish::StatementHandle）行40中的方法执行得到1，预期0（-1）####################################################################################################################################################################################

消息类型0x31从服务器到达，而空闲消息类型0x5a从服务器到达，而空闲消息类型0x74从服务器到达，而空闲消息类型0x6e从服务器到达，而空闲消息类型0x5a在空闲时从服务器到达

这是密码。（如果选择运行它，请记住设置正确的密码。它创建/操作名为“enummappings”的表，但不执行其他操作。）肉在add-enum-mappings（）中。其他一切都只是设置。哦，并且dbh（）为每个线程创建一个单独的DB连接。根据PostgreSQL文档，这是必要的。

#!/usr/bin/env perl6

use DBIish;
use Log::Async;

my Lock $db-lock;
my Lock $deletion-lock;
my Lock $insertion-lock;

INIT {
    logger.send-to($*ERR);
    $db-lock .= new;
    $deletion-lock .= new;
    $insertion-lock .= new;
}

# Get a per-thread database connection.
sub dbh() {
    state %connections;
    my $dbh := %connections<$*THREAD.id>; # THIS IS WRONG. Should be %connections{$*THREAD.id}.
    $db-lock.protect: {
        if !$dbh.defined {
            $dbh = DBIish.connect('Pg', :host<127.0.0.1>, :port(5432), :database<postgres>,
                :user<postgres>, :password<PASSWORD>);
        }
    };

    return $dbh;
}

sub create-table() {
    my $name = 'enummappings';
    my $column-spec =
        'enumname TEXT NOT NULL, name TEXT NOT NULL, value INTEGER NOT NULL, UNIQUE(enumname, name)';
    my $version = 1;
    my $sth = dbh.prepare("CREATE TABLE IF NOT EXISTS $name ($column-spec);");
    $sth.execute;

    # And add the version number to a version table:
    dbh.execute:
        "CREATE TABLE IF NOT EXISTS tableversions (name TEXT NOT NULL UNIQUE, version INTEGER NOT NULL);";
    $sth = dbh.prepare:
        'INSERT INTO tableversions (name, version) VALUES (?, ?)
            ON CONFLICT (name)
                DO
                    UPDATE SET version = ?;';
    $sth.execute($name, $version, $version);
}

sub add-enum-mappings($enumname, @names, @values --> Hash) {
    $deletion-lock.protect: {
        my $sth = dbh.prepare('DELETE FROM enummappings WHERE enumname = ?;');
        $sth.execute($enumname);
    };

    my @rows = (^@names).map: -> $i {$enumname, @names[$i], @values[$i]};
    info "Inserting @rows.elems() rows...";
    $insertion-lock.protect: {
        my $sth = dbh.prepare('INSERT INTO enummappings (enumname,name,value) VALUES '~
            ('(?,?,?)' xx @rows.elems).join(',') ~ ';');
        $sth.execute(@rows>>.list.flat);
    };

    return %(status => 'okay');
}

# Create a bunch of long enums with random names, keys, and values.
sub create-enums(--> Hash[Hash]) {
    my @letters = ('a'..'z', 'A'..'Z').flat;
    my Hash %enums = ();
    for ^36 {
        my $key = @letters.pick(10).join;
        for ^45 {
            my $sub-key = @letters.pick(24).join;
            %enums{$key}{$sub-key} = (0..10).pick;
        }
    }
    return %enums;
}

sub MAIN() {
    create-table;

    await do for create-enums.kv -> $enum-name, %enum {
        start {
            add-enum-mappings($enum-name, %enum.keys, %enum.values);
            CATCH { default { note "Got error adding enum: " ~ .gist; } }
        };
    }
}

我在视窗10上，有一台8核电脑。我知道我可以单线程插入数据，但是如果游戏一次获得一百个连接呢？我需要永远解决这个问题。

Answer 1

我怀疑你的问题在这里：

my $dbh := %connections<$*THREAD.id>;

%散列

错误发生后，您只有一个在所有线程之间共享的DB连接，我想这就是DBIish（或底层postgresql C客户端库）不满意的地方。