带有运算符优先规则的Perl 6语法示例

Question

我对Perl非常陌生，希望创建一种具有优先使用新的Perl 6语法功能的运算符的域特定语言。例如以正确的方式解析“1 2*6”。

到目前为止，我所找到的文档（例如本文）还没有针对具有优先声明的运算符的语法规则的示例。

我有一个非常简单的例子

use v6;

#use Grammar::Tracer;

grammar TestGrammar {

    token TOP {
        <digit> <infix> <digit>
    }

    token infix:sym<times> is equiv(&infix:<*>) { <sym> }

}

sub MAIN() {
    my $text = "1 times 2" ;
    say $text ;

    my $match = TestGrammar.parse($text);
    say $match;
}

这给了我

No such method 'infix' for invocant of type 'TestGrammar'

我只想构造一个抽象语法树。

Answer 1

恐怕你不能在语法中设置中缀运算符和定义优先级等。这些当前仅适用于扩展Perl 6。

这里有一个可能的方法。它在加法之前解析乘法项，还允许使用单词或符号，例如倍或*。

use v6;

grammar TestGrammar {

    rule TOP      { <expr=.add> }

    rule add      { <expr=.multiply> +% [ <add-op> ] }
    rule multiply { <digit> +%  [ <mult-op> ] }

    proto token mult-op {*}
    token mult-op:sym<times>   { <sym>|'*' }
    token mult-op:sym<divided> { <sym>|'/' }

    proto token add-op {*}
    token add-op:sym<plus>     { <sym>|'+' }
    token add-op:sym<minus>    { <sym>|'-' }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2 * 6", "4 times 7 minus 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}

请注意，%是分隔符运算符<代码>

S05确实提到，尽管规则和标记是特殊的方法，但它们都可以声明为multi，并像常规方法一样接受参数。

这种方法利用递归和多分派来实现操作员优先级级别。

use v6;

grammar TestGrammar {

    rule TOP                { <expr(3)> }

    # operator multi-dispatch, loosest to tightest
    multi token op(3) {'+'|'-'|add|minus}
    multi token op(2) {'*'|'/'|times|divided}
    multi token op(1) {'**'}

    # expression multi-dispatch (recursive)
    multi rule expr(0)      { <digit> | '(' ~ ')' <expr(3)> }
    multi rule expr($pred)  { <expr($pred-1)> +% [ <op($pred)> ] }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2**3 * 6", "4 times (7 minus 3) * 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}