在VBScript中设置当前日期和时间的格式

Question

我在想是否有人能帮我。

我是一个非常新的ASP我想格式化当前的日期和时间如下：

yyyy-mm-dd hh:mm:ss

但我能做的只有以下几点

Response.Write Date

有人能帮我一下吗。

Answer 1

在传统ASP中，日期格式选项是有限的。默认情况下，有一个formatdatetime()函数可以根据服务器的区域设置以各种方式格式化日期。

为了更好地控制日期格式，虽然有内置的日期时间函数

>

year（date)-返回表示年份的整数。通过date()将返回当前年份。

month（date）-返回1到12（含12）之间的整数，表示一年中的月份。传递date()将返回一年中的当前月份。

monthname(month[,abbv])-返回指示指定月份的字符串。将month（Date（））作为月份传入将返回当前月份字符串。正如@Martha所建议的

day（date)-返回1到31（含31）之间的整数，表示月份的某一天。传递date()将返回当月的当天。

hour（time)-返回一个介于0和23之间（含23）的整数，表示一天中的小时。传递time()将返回当前小时。

minute(time)-返回0到59（含）之间的整数，表示每小时中的分钟。传递time()将返回当前分钟。

second(time)-返回0到59（含）之间的整数，表示每分钟的秒。传递time()将返回当前秒。

重要：设置日期/时间值的格式时，始终要先存储日期/时间值。此外，在尝试格式化之前，应应用任何所需的计算(dateadd()等），否则将得到意外的结果。

函数month()、day()、hour()、minute()和second()都返回整数。幸运的是，有一个简单的解决方法，可以让您快速地将这些值填充到右边（“00”&value，2)它所做的是将00追加到值的前面，然后从右边取前两个字符。这确保了所有的个位数值都以0作为前缀返回。

Dim dd, mm, yy, hh, nn, ss
Dim datevalue, timevalue, dtsnow, dtsvalue

'Store DateTimeStamp once.
dtsnow = Now()

'Individual date components
dd = Right("00" & Day(dtsnow), 2)
mm = Right("00" & Month(dtsnow), 2)
yy = Year(dtsnow)
hh = Right("00" & Hour(dtsnow), 2)
nn = Right("00" & Minute(dtsnow), 2)
ss = Right("00" & Second(dtsnow), 2)

'Build the date string in the format yyyy-mm-dd
datevalue = yy & "-" & mm & "-" & dd
'Build the time string in the format hh:mm:ss
timevalue = hh & ":" & nn & ":" & ss
'Concatenate both together to build the timestamp yyyy-mm-dd hh:mm:ss
dtsvalue = datevalue & " " & timevalue

Call Response.Write(dtsvalue)

注意：您可以在一次调用中构建日期字符串，但决定将其分解为三个html" target="_blank">变量，以便于阅读。

• 如何设置日期格式
• 解析日期字符串的示例（答案提供了获取日期字符串格式并将其解析为有效的Date变量的方法）。
• 设置前一天的日期格式使用VBScript设置yyyymmdd格式（为什么在执行格式设置之前存储日期/时间很重要的示例）