正确安装Java8和Java7

Question

我在windows 7机器上安装了JDK 1.7，在安装JDK 1.8 u20后，出现以下错误：

C:\>java -version
Error: Registry key 'Software\JavaSoft\Java Runtime Environment'\CurrentVersion'
has value '1.8', but '1.7' is required.
Error: could not find java.dll
Error: Could not find Java SE Runtime Environment.

我的PATH变量指向旧版本（即1.7）。

这里出了什么问题，我如何使用java 8和java 7？

Answer 1

你不能既有蛋糕又吃当您将PATH变量设置为JDK1.8时，问题应该得到解决。您可以在JDK1.7中运行程序，方法是使用命令提示符中的SETPATH手动设置PATH，也可以转到JDK1.7目录并从那里运行程序。但是在您的路径中只能有一个JDK。

Answer 2

在开始菜单中键入“regedit”打开注册表编辑器

转到左侧注册表资源管理器/树菜单上的“HKEY_LOCAL_MACHINE”

单击“HKEY_本地_机器”注册表中的“软件”

单击“软件”注册表中的“JavaSoft”

点击"Java运行时环境"在"JavaSoft"列表的注册表在这里你可以看到不同版本的安装java

单击“Java运行时环境”-在右边您将看到4-5行。请选择“当前版本”并右键单击（选择修改选项）将版本更改为“1.7”

现在魔法已经完成了

Answer 3

问题是Java8安装了很多你并不真正需要的东西：

>

\windows\system 32包含Java8java.exe，javaw.exe和javaws.exe.您的路径可能在开头附近有system 32，所以这些通常会在默认情况下运行。

系统路径变量以C：\编程数据\Oracle\Java\javapath开头。此文件夹包含java.exe、javaw.exe和javaws.exe作为JRE 8可执行文件的符号链接。

我已经删除了system32文件，并从系统路径中删除了C:\programdata\Oracle\Java\javapath。这似乎可以解决问题。我现在可以通过将JAVA_主页和路径指向适当的文件夹来切换版本。

甲骨文似乎决心让多个版本难以运行。这在JRE中是可以理解的，但在JDK中却是疯狂的，因为开发人员几乎总是需要多个版本的Java。

编辑：我发现这个批处理脚本对于切换JDK很有用。用法：jdk.bat6|7|8。您可能必须编辑Java的安装位置。

@echo off
if "%1"=="" goto report
set _version=%1
shift
if "%1"=="DBG" shift & echo on
set _command=%1 %2 %3 %4 %5

set _jdkdir=
set _jdkver=
for /D %%f in ("C:\Program Files\java\"jdk1.%_version%.*) do call :found "%%f"
if "%_jdkdir%"=="" goto notfound

set java_home=C:\Program Files\java\%_jdkdir%
call :javapath
path %new_path%
goto :report

:javapath
    setlocal enabledelayedexpansion
    set _jdirs=
    for /D %%j in ("C:\Program Files\java\*") do set _jdirs=!_jdirs!#%%~fj\bin
    set _jdirs=%_jdirs%#

    set _javabin=%java_home%\bin
    set _fpath="%PATH:;=" "%"
    call :checkpath %_fpath%
    endlocal & set new_path=%_javabin%
goto :eof

:checkpath
    if _%1==_ goto :eof
    echo %_jdirs% | find /i "#%~1#" 1>nul 2>&1
    set _err=%errorlevel%
    if not %_err%==0 set _javabin=%_javabin%;%~1
    if %_err%==0 echo Removed %~1 from path
    shift
    goto :checkpath

:report
javac -version
%_command%
goto :eof

:notfound
echo No JDK matching [C:\Program Files\java\jdk1.%_version%.*] found.
goto :eof

:found
set _jdkdir=%~n1%~x1
for /F "tokens=2,3 delims=." %%a in ("%_jdkdir%") do set _jdkver=1.%%a.%%b
goto :eof