Jenkins共享库中未调用构造函数

Question

我正在尝试开发共享库，目录结构如下

• src/com/mycomapny
  • 我的测试。棒极了
  • 测试。棒极了

  我的Jenkinsfile调用test.groovy中唯一可用的方法，需要输入。它导入MyTest并创建对象，调用构造函数，然后是执行MyTest.groovy文件中可用功能的实际方法

  在这里，构造函数类从未从全局vars/test调用过。棒极了

  我尝试从groovy调用类和方法，它工作正常，但当我从jenkinsfile调用它时，它不工作。我不知道为什么我不能调用构造函数和我错过了什么。

  我已将@NonCPS置于上述测试中。groovy方法，但仍然不起作用。

  //MyTest.groovy
  package com.mycompany
  
  class MyTest implements Serializable {
      public _notification
  
      MyTest(Closure content) {
          notification = [:]
          content.resolveStrategy = Closure.DELEGATE_FIRST
          content.delegate = notification
          content()
          println("Entered Constructor")
          this._notification = notification
      }
  
  }
  
  //test.groovy
  import com.mycopany.MyTest
  def notify(Closure content) {
      println("This is line i am getting in the output but nothing after that")
      MyTest tester = new MyTest(content)
      println(tester._notification.colorcode)
  } 
  
  //Jenkinsfile
  @library("MysharedLibrary@master") _
  pipeline{
      stages {
           stage {
               steps {
                   test.notify {
                        buildno = 12
                        jobname = "Mytest"
                        colorcode = "Blue"
                   }
               }
           }
      }
  }
  

  在这里，我只想从jenkins文件调用构造函数，并在我的vars/test中打印输入值的值。棒极了。

  EDIT1：当我使用@NonCPS上面的方法"def nofity"我的构建是越来越成功，但我得到的除了打印语句在第一行的通知方法。

  如果我不使用@NonCPS，我会得到以下异常

  Error when executing always post condition:
  com.cloudbees.groovy.cps.impl.CpsCallableInvocation
  
  hudson.remoting.ProxyException:com.cloudbees.groovy.cps.impl.CpsCallableInvocation
  Finished: FAILURE
  

Answer 1

您看到此错误是因为您正在构造函数内调用闭包。相反，您应该将其提取到单独的方法中。构造函数应用于初始化过程中传递的值初始化对象。例如，通常的做法是将引用传递给WorkflowScript对象，因此可以使用管道步骤，如echo。

考虑以下对共享库代码的更改：

src/com/mycompany/MyTest。棒极了

package com.mycompany

class MyTest {
  final Map notification = [:]
  final Script script

  MyTest(Script script) {
    this.script = script
  }

  def notify(Closure content) {
    processContent(content)
    script.echo "Notification processed = ${notification}"
  }

  def processContent(Closure content) {
    content.resolveStrategy = Closure.DELEGATE_FIRST
    content.delegate = notification
    content()
  }
}

变量/测试。棒极了

import com.mycompany.MyTest
import groovy.transform.Field

@Field
final MyTest tester = new MyTest(this)

def notify(Closure content) {
    println("This is line i am getting in the output but nothing after that")
    tester.notify(content)
    println(tester.notification.colorcode)
}

詹金斯档案

pipeline {
    agent any

    stages {
         stage("Test") {
             steps {
                 script {
                     test.notify {
                          buildno = 12
                          jobname = "Mytest"
                          colorcode = "Blue"
                     }
                 }
             }
         }
    }
}

输出：

[Pipeline] Start of Pipeline
[Pipeline] node
[Pipeline] {
[Pipeline] stage
[Pipeline] { (Test)
[Pipeline] script
[Pipeline] {
[Pipeline] echo
This is line i am getting in the output but nothing after that
[Pipeline] echo
Notification processed = [buildno:12, jobname:Mytest, colorcode:Blue]
[Pipeline] echo
Blue
[Pipeline] }
[Pipeline] // script
[Pipeline] }
[Pipeline] // stage
[Pipeline] }
[Pipeline] // node
[Pipeline] End of Pipeline

请记住，这只是重构共享管线库代码的一种方式。您的主要目标应该是从类构造函数内部移动闭包调用。这取决于你把它放在哪里，所以它最适合你。