从 Jenkins Pipeline 中的 Groovy 变量创建 JSON 字符串

Question

我必须在Groovy中创建这个JSON文件。我尝试了很多事情（JsonOutput.toJson（）/JsonSlurper）。parseText（））失败。

{
   "attachments":[
      {
         "fallback":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
         "pretext":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
         "color":"#D00000",
         "fields":[
            {
               "title":"Notes",
               "value":"This is much easier than I thought it would be.",
               "short":false
            }
         ]
      }
   ]
}

这是为了向Slack发布Jenkins构建消息。

Answer 1

如果你被困在一个使用沙箱和Jenkins脚本安全插件的安装上，没有可能添加白名单类/方法，我发现的唯一方法如下:

def slackSendOnRestrictedContext(params) {

    if (params.attachments != null) {
        /* Soooo ugly but no other choice with restrictions of
           Jenkins Script Pipeline Security plugin ^^ */
        def paramsAsJson = JsonOutput.toJson(params)
        def paramsAsJsonFromReadJson = readJSON text: paramsAsJson
        params.attachments = paramsAsJsonFromReadJson.attachments.toString()
    }

    slackSend (params)
}

Answer 2

当我试图做一些事情时（我认为）发现这个问题应该很简单，但另一个答案没有解决。如果已经将JSON作为字符串加载到变量中，如何将其转换为本机对象？显然，您可以执行＜code＞新的JsonSlurperClassic（）。parseText（json），正如另一个答案所暗示的那样，但Jenkins有一种本地方法可以做到这一点：

node () {
  def myJson = '{"version":"1.0.0"}';
  def myObject = readJSON text: myJson;
  echo myObject.version;
}

希望这能帮助别人。

编辑：正如评论中所解释的，“原生”不太准确。

Answer 3

JSON 是一种使用人类可读文本传输由属性-值对和数组数据类型组成的数据对象的格式。因此，通常 json 是格式化文本。

在时髦的json对象中只是一系列映射/数组。

使用JsonSlurperClassic解析json

//use JsonSlurperClassic because it produces HashMap that could be serialized by pipeline
import groovy.json.JsonSlurperClassic

node{
    def json = readFile(file:'message2.json')
    def data = new JsonSlurperClassic().parseText(json)
    echo "color: ${data.attachments[0].color}"
}

使用管道解析json

node{
    def data = readJSON file:'message2.json'
    echo "color: ${data.attachments[0].color}"
}

从代码构建json并将其写入文件

import groovy.json.JsonOutput
node{
    //to create json declare a sequence of maps/arrays in groovy
    //here is the data according to your sample
    def data = [
        attachments:[
            [
                fallback: "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                pretext : "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                color   : "#D00000",
                fields  :[
                    [
                        title: "Notes",
                        value: "This is much easier than I thought it would be.",
                        short: false
                    ]
                ]
            ]
        ]
    ]
    //two alternatives to write

    //native pipeline step:
    writeJSON(file: 'message1.json', json: data)

    //but if writeJSON not supported by your version:
    //convert maps/arrays to json formatted string
    def json = JsonOutput.toJson(data)
    //if you need pretty print (multiline) json
    json = JsonOutput.prettyPrint(json)

    //put string into the file:
    writeFile(file:'message2.json', text: json)

}