在spock中运行测试时缺少PropertyException

Question

我用groovy编写了以下测试（使用spock框架时）：

def "#checkPassword check if passwd match"() {
    given:
    def allowedPasswords = ["1", "2"]

    expect:
    myStrategy.checkPassword(myModel, input) == result

    where:
    input | result
    allowedPasswords   | true
}

然而，当我运行它时，allowedPasswords字段似乎丢失了。我得到以下错误：

groovy.lang.MissingPropertyException: No such property: allowedPasswords for class: 

我想知道为什么，因为我在given一节中声明了它。你能帮我吗？

Answer 1

你的问题的原因是其中：块逻辑上属于文本夹具-记住，在@Unroll的情况下，变量值甚至会被编译成方法名！请参阅下面的示例代码。即，，其中：在给定的块之前计算，因此您不能期望它知道稍后在测试期间初始化的局部变量。

至于测试代码的其余部分：如果没有重用allowePassword，我的建议是只内联它。您已经接受的答案或我将向您展示的作为替代选项的答案只有在您重新使用所讨论的变量并且不想为了使测试维护更容易而将其内联两次时才会使用。那么德米特里的答案当然是好的。然而，如果不重用，它会稍微混淆测试代码，使其更难阅读和理解。我建议您努力实现可读性，因为一个好的BDD测试是应用程序行为的规范，因此Spock测试基类名称规范和Geb基类名称GebSpec。

至于Dmitry的回答，我只想说明，您可以使用好的旧静态作为@Shared的替代，还可以提供一些重复使用的示例代码，使其更有意义，也更接近您自己的测试用例。我不希望你以任何方式接受这个答案而不是他的答案，因为他在我面前的回答是正确的。我只是在这里分享更多的细节，没有什么新鲜事。在他的回答中，我只是没有解释为什么您的代码不起作用，所以我也觉得有必要回答：：-）

package de.scrum_master.stackoverflow

import spock.lang.Specification
import spock.lang.Unroll

class AllowedPasswordsTest extends Specification {
  static allowedPasswords = ["1", "2"]

  @Unroll
  def "password check for '#input' should return #result"() {
    expect:
    checkPassword(input) == result

    where:
    input << allowedPasswords + ["3", "oops", "  ", null]
    result = input in allowedPasswords
  }

  static boolean checkPassword(String input) {
    return input?.trim()?.matches("[12]")
  }
}

Answer 2

看起来就像你在寻找@Shared：

import spock.lang.Shared
import spock.lang.Specification

class SpockTest extends Specification {
    @Shared allowedPasswords = ["1", "2"]

    def "#checkPassword check if passwd match"() {
        expect:
        checkPassword(input) == result

        where:
        input << allowedPasswords
        result << allowedPasswords
    }

    static String checkPassword(String input) {
        return input
    }
}