如何从Spock测试进行CDI/SE？

Question

我一直在使用CDIUnit和其他各种形式的CDI/SE解决方案来实现测试（junit），这些测试可以减少模拟，并更多地使用我的应用程序堆栈（我想是集成测试）。

无论如何，我也非常喜欢Spock进行测试，我认为应该抓紧时间从CDI/SE空间和Spock中混合一些东西，以便能够制定能够访问大部分CDI内容的规范。

许多CDI的单元运行程序（CDIUnit、WeldjUnit、deltaspike、为SE做cdi或Weld的随机博客片段）都是JUnit运行程序，似乎与Spock不太匹配。经过多次修补，我已经提炼出一个非常简单的东西：用非常简单的@Inject焊接/se spock。但它不起作用。

似乎weld确实“启动”了，我的可注射体的后构造函数也启动了。但是，在Spock feature方法中，对可注入的引用为null。在进一步的测试中，我使用@InjectSetter而不是实例变量，setter似乎使用了非空引用，但在我的feature方法启动时；引用再次为空。我还把Weld和container@Shared弄得一团糟，并试图在setupSpec（）生命周期方法中初始化；同样的结果。

是否可以通过Spock测试进行简单的CDI操作？

这里有一个史波克的样本，展示了我正在努力实现的目标：

package fhw

import spock.lang.Specification
import javax.inject.Inject
import org.jboss.weld.environment.se.Weld
import org.jboss.weld.environment.se.WeldContainer
import spock.lang.Shared

public class Chompers
    extends Specification
{
    def Weld weld
    def WeldContainer container

    def setup()
    {
        println this
        weld = new Weld()
        container = weld.initialize()
        container.instance().select(this.class).get()
        //container.instance().select(this.class)
    }

    @Inject
    def SomethingToTest somethingToTest;

    //@Inject
    //def setSomethingToTest(SomethingToTest sst)
    //{
    //    somethingToTest = sst
    //    println "setter fired  and somethingToTest is null?  " + (null == somethingToTest)
    //}

    def "my first Test"()
    {
        given:
            println "given I used weld wrapper spec From spock (instance " + this + ")"


        when:
            println "when I do something, in this case, like just haveing @Inject annotation"

        then:
            somethingToTest
    }
}

我有点“工作”。不确定原因或方式，甚至不确定它是否有任何好处（对于解决方案）。我想知道更多关于发生了什么以及为什么。样品：

package fhw

import org.junit.runner.RunWith
import spock.lang.*
import org.jboss.weld.environment.se.Weld
import org.jboss.weld.environment.se.WeldContainer
import javax.enterprise.inject.Instance

class WeldSpec
    extends Specification
{

    def Weld weld
    def WeldContainer container
    def me

    def setup()
    {
        weld = new Weld()
        container = weld.initialize()
        me = container.instance().select(this.class).get()
    }

    def cleanup()
    {
        if(weld)
        {
            weld.shutdown()
        }
    }
}

package fhw

import spock.lang.*
import javax.inject.Inject
import fhw.spock.*

public class Bonnie
    extends WeldSpec
{
    @Inject 
    def SomethingToTest somethingToTest;

    def "my silly first cdi-spock test"()
    {        
        when:
            def s = me.somethingToTest.upShift("fred")

        then:
            "FRED" == s 
    }
}

package fhw;

import javax.annotation.PostConstruct;
import javax.inject.Named;


@Named
public class SomethingToTest
{
    public SomethingToTest() {}

    @PostConstruct
    private void init()
    {
        System.out.println("SomethingToTest:  post construction");
    }


    public String upShift(String in)
    {
        String s = null;
        if(null != in)
        {
            s = in.toUpperCase();
        }
        return(s);
    }

}

因此，我观察/推测，真正发生的事情是斯波克创建了我的规范（“this”）的一个实例，然后在使用weld/se的设置中，我使用select（）创建了另一个实例。get（）调用（'me'）。简单的打印显示“我”！='这“实际上是注入发生在通过select（）创建的托管实例上。get（）。我想大概是这样。

所以我想我真正想要的是注射发生在“这个”上。一些谷歌搜索，我偶然发现了这个： CDI注入到现有的对象中，这是类似的东西。我受到DeltaSpike的injectFields的启发，并重构了WeldSpec，比如：

package fhw

import spock.lang.*
import javax.enterprise.inject.spi.BeanManager
import javax.enterprise.inject.spi.InjectionTarget
import org.jboss.weld.environment.se.Weld
import org.jboss.weld.environment.se.WeldContainer
import javax.enterprise.context.spi.CreationalContext
import javax.enterprise.inject.spi.AnnotatedType

class WeldSpec
    extends Specification
{
    def Weld weld
    def WeldContainer container

    def setup()
    {
        weld = new Weld()
        container = weld.initialize()
        BeanManager beanManager = container.getBeanManager()
        CreationalContext<? extends WeldSpec> creationalContext = beanManager.createCreationalContext(null)
        AnnotatedType<? extends WeldSpec> annotatedType = beanManager.createAnnotatedType((Class<? extends WeldSpec>) this.getClass())
        InjectionTarget<? extends WeldSpec> injectionTarget = beanManager.createInjectionTarget(annotatedType)
        injectionTarget.inject(this, creationalContext);            
    }

    def cleanup()
    {
        if(weld)
        {
            weld.shutdown()
        }
    }
}

这是可行的，我的规范更自然一些：

package fhw

import spock.lang.*
import javax.inject.Inject
import fhw.spock.*

public class Bonnie
    extends WeldSpec
{
    @Inject 
    def SomethingToTest somethingToTest;

    def "my silly first cdi-spock test"()
    {        
        when:
            def s = somethingToTest.upShift("fred")

        then:
            "FRED" == s
    }
}

现在来看看这是否有什么好处。。。。

Answer 1

Update2有一个性能问题：由于setup（）在每个特征方法之前运行，因此每个特征方法都会初始化Weld，并扫描类路径和所有。

我把它移动到静态-但在这种情况下没有关闭（我找不到一个地方为它关闭钩子之外，但可能它甚至不需要测试）：

class CdiSpecification extends Specification {

    private static Weld weld
    private static WeldContainer container
    private static BeanManager beanManager

    static {
        weld = new Weld()
        container = weld.initialize()
        beanManager = container.getBeanManager()
    }

    def setup() {
        CreationalContext<? extends CdiSpecification> creationalContext = beanManager.createCreationalContext(null)
        AnnotatedType<? extends CdiSpecification> annotatedType = beanManager.createAnnotatedType((Class<? extends CdiSpecification>) this.getClass())
        InjectionTarget<? extends CdiSpecification> injectionTarget = beanManager.createInjectionTarget(annotatedType)
        injectionTarget.inject(this, creationalContext);
    }

//    def cleanup() {
//        if (weld) {
//            weld.shutdown()
//        }
//    }
}

Answer 2

根据更新2；我有些东西在工作。