使用Inno安装程序在安装过程中删除和注销DLL文件

Question

在我的< code>[Files]部分中，我有以下内容:

; Database password decryption (for PTS importing)
Source: "..\..\..\PTSTools\PTSTools\bin\x86\Release\PTSTools.dll"; \
    DestDir: "{app}"; \
    DestName: "PTSTools_x86.dll"; Flags: ignoreversion
Source: "..\..\..\PTSTools\PTSTools\bin\x64\Release\PTSTools.dll"; \
    DestDir: "{app}"; \
    DestName: "PTSTools_x64.dll"; Flags: ignoreversion; Check: IsWin64

在[运行]部分我有：

Filename: "{dotnet40}\regasm.exe"; Parameters: "PTSTools_x86.dll /codebase"; \
    WorkingDir: "{app}"; Flags: runhidden
Filename: "{dotnet4064}\regasm.exe"; Parameters: "PTSTools_x64.dll /codebase"; \
    WorkingDir: "{app}"; Flags: runhidden; Check: IsWin64

最后，在[UninstallRun]部分，我有：

Filename: {dotnet40}\regasm.exe; Parameters: /u PTSTools_x86.dll; \
     WorkingDir: {app}; \
    Flags: runhidden
Filename: {dotnet4064}\regasm.exe; Parameters: /u PTSTools_x64.dll;  \
    WorkingDir: {app}; \
    Flags: runhidden; Check: IsWin64;

现在，在这个版本的程序中，我已经将这两个DLL文件的功能合并到另一组DLL文件中：

Source: "..\..\..\MSAToolsLibrary\MSAToolsLibrary\bin\x86\Release\MSAToolsLibrary.dll"; \
    DestDir: "{app}"; DestName: "MSAToolsLibrary_x86.dll"; Flags: ignoreversion
Source: "..\..\..\MSAToolsLibrary\MSAToolsLibrary\bin\x64\Release\MSAToolsLibrary.dll"; \
    DestDir: "{app}"; DestName: "MSAToolsLibrary_x64.dll"; Flags: ignoreversion; \
    Check: IsWin64

因此，不再需要 PTSTool DLL 文件。现在，我知道如果它们存在，我可以简单地删除它们：

[InstallDelete]
Type: files; Name: "{app}\PTSTools_x64.dll"
Type: files; Name: "{app}\PTSTools_x86.dll"

但据我所知，这不会像在 [卸载运行] 中那样触发 DLL 文件的注销。

我该怎么做？在安装过程中删除并注销DLL文件（如果存在）？

Answer 1

我不认为您可以使用标准部分轻松实现这一点。

< code>[Run]条目仅出现在< code>[InstallDelete]之后。而在删除DLL之前，您需要反过来先取消注册。

所以你需要 Pascal 脚本。

将BeforeInstall参数添加到[InstallDelete]并取消注册DLL编程。

或者将安装后参数添加到 [运行] 并以编程方式删除 DLL。

后者对您来说工作量较小，因为您已经知道如何使用< code>[Run]来注册。

[Run]
Filename: {dotnet40}\regasm.exe; Parameters: /u PTSTools_x86.dll; \
    WorkingDir: {app}; \
    Check: FileExists(ExpandConstant('{app}\PTSTools_x86.dll')); \
    AfterInstall: DoDeleteFile(ExpandConstant('{app}\PTSTools_x86.dll')); \
    Flags: runhidden
Filename: {dotnet4064}\regasm.exe; Parameters: /u PTSTools_x64.dll;  \
    WorkingDir: {app}; \
    Check: IsWin64 and FileExists(ExpandConstant('{app}\PTSTools_x64.dll')); \
    AfterInstall: DoDeleteFile(ExpandConstant('{app}\PTSTools_x64.dll')); \
    Flags: runhidden

[Code]

{ Cannot use built-in DeleteFile directly in AfterInstall as it's a function,
{ not a procedure. And this way we can add some error handling too. }
procedure DoDeleteFile(FileName: string);
begin
  if DeleteFile(FileName) then
  begin
    Log(Format('"%s" deleted', [FileName]));
  end
    else
  begin
    MsgBox(Format('Failed to delete "%s"', [FileName]), mbError, MB_OK);
  end;
end;