如何在Inno Setup Pascal脚本中取消引用指针？

Question

我在Inno Setup Script中从DLL文件调用一个函数，它的返回类型是PAnsiChar。为了获取整个字符串，我需要取消引用指针，但标准的Pascal语法在这里不起作用。有可能做到这一点吗？

function SQLDLL : PAnsiChar;
external 'GetSQLServerInstances@files:IsStartServer.dll stdcall setuponly';

function NextButtonClick(CurPage: Integer): Boolean;
var
  hWnd: Integer;
  Str : AnsiString;
begin
  if CurPage = wpWelcome then begin
    hWnd := StrToInt(ExpandConstant('{wizardhwnd}'));

    MessageBox(hWnd, 'Hello from Windows API function', 'MessageBoxA', MB_OK or MB_ICONINFORMATION);

    MyDllFuncSetup(hWnd, 'Hello from custom DLL function', 'MyDllFunc', MB_OK or MB_ICONINFORMATION);

    Str := SQLDLL;
    try
      { if this DLL does not exist (it shouldn't), an exception will be raised }
      DelayLoadedFunc(hWnd, 'Hello from delay loaded function', 'DllFunc', MB_OK or MB_ICONINFORMATION);
    except
      { handle missing dll here }
    end;
  end;
  Result := True;
end;

我只有DLL文件。原始语言是德尔福。

我更新到最新版本的Inno Setup 6.0.3，并在我家用Windows 10 Pro机器上测试了以下代码：

[Setup]
AppName=My Program
AppVersion=1.5
WizardStyle=modern
DefaultDirName={autopf}\My Program
DisableProgramGroupPage=yes
DisableWelcomePage=no
UninstallDisplayIcon={app}\MyProg.exe
OutputDir=userdocs:Inno Setup Examples Output

[Files]
Source: "MyProg.exe"; DestDir: "{app}"
Source: "MyProg.chm"; DestDir: "{app}"
Source: "Readme.txt"; DestDir: "{app}"; Flags: isreadme
Source: "IsStartServer.dll"; Flags: dontcopy

[Code]
function SQLDLL : PAnsiChar;
external 'GetSQLServerInstances@files:IsStartServer.dll stdcall';

function NextButtonClick(CurPage: Integer): Boolean;
var
  Str : PAnsiChar;
begin
  Str := SQLDLL;
  Result := True;
end; 

我不明白为什么它必须查看我的“临时”目录？我还听说这个问题可能与Windows 10 UAC的组策略有关，但我不确定我应该做些什么来消除这个错误。

Answer 1

在Inno Setup Pascal脚本中不能取消对指针的引用。

但也有许多黑客允许这样做。这些技巧非常具体，因此取决于特定的用例。

尽管在您的特定情况下，指向字符数组的指针在API中很普遍，Inno Setup Pascal脚本(类似于Delphi)可以将指向字符数组的指针分配给一个字符串。

因此，您应该能够简单地将PChar分配给AnsiString：

function ReturnsPAnsiChar: PAnsiChar; extern '...';

var
  Str: AnsiString;
begin
  Str := ReturnsPAnsiChar;
end;

请参阅如何将字符串从DLL返回到Inno安装程序？

Answer 2

如果我理解正确，您的SQLDLL本身管理一些内存缓冲区并返回指向Unicode字符串的指针（不是ANSI，这就是为什么根据您的评论，当您尝试PAnsiChar时只有一个字符）。

Inno Setup不直接支持这一点，甚至没有PWideChar类型。但是，我们可以自己处理。我们只需要分配一个大小合适的Inno字符串并手动复制数据。

下面是一个如何做到这一点的示例。它使用GetCommandLineW作为返回PWideChar的示例函数，但您可以使用SQLDLL函数执行同样的操作。

< li >从外部函数获取指针，并将其存储在一个变量中(一个< code>Cardinal -在我的示例中，我为它创建了一个typedef PWideChar)。 < li >使用< code>lstrlenW获取字符串长度。 < li >创建一个空的常规< code >字符串，但使用< code>SetLength将其设置为正确的长度。这将保留足够的容量，我们可以在下一步将实际内容写入其中。 < li >使用< code>lstrcpyW将指针引用的字符串复制到常规< code>String变量。 < ul > < li >(如果您使用的是ANSI版本的Inno Setup:请使用< code>WideCharToMultiByte，参见本文末尾的我的更新。)

诀窍是导入 lstrcpyW，这样目标指针被声明为字符串，但源指针被声明为基数（或我的 typedef PWideChar 在这里）。

type
  PWideChar = Cardinal; { Inno doesn't have a pointer type, so we use a Cardinal instead }

{ Example of a function that returns a PWideChar }
function GetCommandLineW(): PWideChar;
external '[e-mail] stdcall';

{ This function allows us to get us the length of a string from a PWideChar }
function lstrlenW(lpString: PWideChar): Cardinal;
external '[e-mail] stdcall';

{ This function copies a string - we declare it in such a way that we can pass a pointer
  to an Inno string as destination
  This works because Inno will actually pass a PWideChar that points to the start of the
  string contents in memory, and internally the string is still null-terminated
  We just have to make sure that the string already has the right size beforehand! }
function lstrcpyW_ToInnoString(lpStringDest: String; lpStringSrc: PWideChar): Integer;
external '[e-mail] stdcall';

function InitializeSetup(): Boolean;
var
  returnedPointer: PWideChar; { This is what we get from the external function }
  stringLength: Cardinal; { Length of the string we got }
  innoString: String; { This is where we'll copy the string into }
begin
  { Let's get the PWideChar from the external function }
  returnedPointer := GetCommandLineW();

  { The pointer is actually just a renamed Cardinal at this point: }
  Log('String pointer = ' + IntToStr(returnedPointer));

  { Now we have to manually allocate a new Inno string with the right length and
    copy the data into it }

  { Start by getting the string length }
  stringLength := lstrlenW(returnedPointer);
  Log('String length = ' + IntToStr(stringLength));

  { Create a string with the right size }
  innoString := '';
  SetLength(innoString, stringLength);

  { This check is necessary because an empty Inno string would translate to a NULL pointer
    and not a pointer to an empty string, and lstrcpyW cannot handle that. }
  if StringLength > 0 then begin
    { Copy string contents from the external buffer to the Inno string }
    lstrcpyW_ToInnoString(innoString, returnedPointer);
  end;

  { Now we have the value stored in a proper string variable! }
  Log('String value = ' + innoString);

  Result := False;
end;

如果将其放入安装程序并运行，则会看到如下输出：

[15:10:55,551]   String pointer = 9057226
[15:10:55,560]   String length = 106
[15:10:55,574]   String value = "R:\Temp\is-9EJQ6.tmp\testsetup.tmp" /SL5="$212AC6,121344,121344,Z:\Temp\testsetup.exe" /DEBUGWND=$222722 

如您所见，命令行字符串（我们作为 PWideChar 获得）被正确复制到常规字符串变量中，并且可以在最后正常访问。

更新:如果您使用的是Inno Setup的ANSI版本，而不是Unicode，单独使用这段代码是不行的。需要的更改如下:不使用< code>lstrcpyW，而是使用< code>WideCharToMultiByte:

function WideCharToMultiByte_ToInnoString(CodePage: Cardinal; dwFlags: Cardinal; lpWideCharStr: PWideChar; cchWideChar: Cardinal; lpMultiByteStr: String; cbMultiByte: Cardinal; lpDefaultChar: Cardinal; lpUsedDefaultChar: Cardinal): Integer;
external '[e-mail] stdcall';

{ Later on: Instead of calling lstrcpyW_ToInnoString, use this:
  Note: The first parameter 0 stands for CP_ACP (current ANSI code page), and the
  string lengths are increased by 1 to include the null terminator }
WideCharToMultiByte_ToInnoString(0, 0, returnedPointer, stringLength + 1, innoString, stringLength + 1, 0, 0);