使用Inno Setup进行静默安装的默认组件

Question

我正在Inno安装程序中开发一个安装文件。当用户选择“自定义”时，它有3个不同的可选组件要安装。

它工作正常，但当传递/SILENT参数时，不会安装任何组件。我想是因为没有检查组件。

…这是相关的代码片段：

[Types]
Name: custom; Description: {cm:instCustom}; Flags: iscustom
Name: full; Description: {cm:instFull}

[Components]
Name: Programador; Description: {cm:cmpProgramador}; Types: full
Name: Usuario; Description: {cm:cmpUsuario}; Types: full
Name: Reporte; Description: {cm:cmpReporte}; Types: full

[Icons]
Name: {group}\{cm:cmpProgramador}; Filename: {app}\Programador\{#MyAppExeNameA}; Components: Programador
Name: {group}\{cm:cmpUsuario}; Filename: {app}\Usuario\{#MyAppExeNameB}; Components: Usuario
Name: {group}\{cm:cmpReporte}; Filename: {app}\Reporte\{#MyAppExeNameC}; Components: Reporte
Name: {group}\Desinstalar MIVES; Filename: {uninstallexe}

[Registry]
Root: HKCU; Subkey: Software\UPC; Flags: uninsdeletekey
Root: HKCU; Subkey: Software\UPC\MIVES
Root: HKLM; Subkey: Software\UPC; Flags: uninsdeletekey
Root: HKLM; Subkey: Software\UPC\MIVES
Root: HKLM; Subkey: Software\UPC\MIVES\Settings; ValueType: string; ValueName: InstallPath; ValueData: {app}

; file association depens of the components selected
Root: HKCR; Subkey: .mip; ValueType: string; ValueData: mip_auto_file; Flags: uninsdeletekey; Components: Programador
Root: HKCR; Subkey: mip_auto_file; Flags: uninsdeletekey; Components: Programador
Root: HKCR; Subkey: mip_auto_file\shell\open\command; ValueType: expandsz; ValueData: {app}\Programador\{#MyAppExeNameA} %1; Components: Programador

Root: HKCR; Subkey: .miu; ValueType: string; ValueData: miu_auto_file; Flags: uninsdeletekey; Components: Usuario
Root: HKCR; Subkey: miu_auto_file; Flags: uninsdeletekey; Components: Usuario
Root: HKCR; Subkey: miu_auto_file\shell\open\command; ValueType: expandsz; ValueData: {app}\Usuario\{#MyAppExeNameB} %1; Components: Usuario

Root: HKCR; Subkey: .mir; ValueType: string; ValueData: mir_auto_file; Flags: uninsdeletekey; Components: Reporte
Root: HKCR; Subkey: mir_auto_file; Flags: uninsdeletekey; Components: Reporte
Root: HKCR; Subkey: mir_auto_file\shell\open\command; ValueType: expandsz; ValueData: {app}\Reporte\{#MyAppExeNameC} %1; Components: Reporte

[Files]
Source: {#MyAppExeNameA}; DestDir: {app}\Programador; Flags: promptifolder; Components: Programador
Source: {#MyAppExeNameB}; DestDir: {app}\Usuario; Flags: promptifolder; Components: Usuario
Source: {#MyAppExeNameC}; DestDir: {app}\Reporte; Flags: promptifolder; Components: Reporte

我需要在传递 /silent 或 /verysilent 参数时默认安装三个组件之一（组件“Usuario”）。

我想我必须使用检查：WizardSilent，但我不知道在哪里。事实上，我尝试在Components部分添加WizardSilent，但没有任何反应：

[Components]
Name: Programador; Description: {cm:cmpProgramador}; Types: full
Name: Usuario; Description: {cm:cmpUsuario}; Types: full; Check: WizardSilent

在“文件”部分中都没有：

[Files]
Source: {#MyAppExeNameB}; DestDir: {app}\Usuario; Flags: promptifolder; Components: Usuario; Check: WizardSilent

以下是我需要的：

< Li > < code > MIVES _ 211 . exe/SP-/very silent

编辑：我想我已经找到了一个解决方案，但我不知道这是否是一个好的解决方案。刚刚添加了一个新类型，包括向导静默检查：

[Types]
Name: silent; Description: {cm:instCustom}; Check: WizardSilent
Name: custom; Description: {cm:instCustom}; Flags: iscustom
Name: full; Description: {cm:instFull}

并在组件部分使用它，组件“Usario”（默认情况下，我希望在静默安装中安装的组件）：

[Components]
Name: Programador; Description: {cm:cmpProgramador}; Types: full
Name: Usuario; Description: {cm:cmpUsuario}; Types: full silent
Name: Reporte; Description: {cm:cmpReporte}; Types: full

现在，它真的如我所愿。但我不希望有两种类型具有相同的描述，除非安装向导中只显示一种。

这是个好主意吗？

谢谢！

Answer 1

我认为你的设置在概念上是错误的。

静默安装应安装典型/默认/通用安装。现在看起来默认安装是“完整”安装，但您希望静默安装的行为有所不同。这似乎不对。

因此，您应该具有默认的“典型”安装类型，带有“Usuario”组件。就像您现在拥有“静音”类型一样。但是，即使在交互式安装中，“典型”类型也是有意义的。

[Types]
Name: typical; Description: "Typical"
Name: full; Description: "Full"
Name: custom; Description: "Custom"; Flags: iscustom

[Components]
Name: Programador; Description: "Programador"; Types: full
Name: Usuario; Description: "Usuario"; Types: full typical
Name: Reporte; Description: "Reporte"; Types: full

无论如何，/SILENT 应该始终伴随着 /LOADINF 或至少 /COMPONENTS 或 /TYPE。

您的“静默”类型的解决方案，虽然是一个黑客，但会有些效果，因为< code>Check: WizardSilent会在交互式安装中隐藏这种类型。

顺便说一句，请注意，在升级时，安装程序将使用以前(可能是交互式的)安装中选择的组件。