Excel VBA MySql参数化更新“无效的参数类型”

Question

我正在创建一个界面，用户可以使用excel无缝更改SQL数据库。我可以很好地检索数据，但当更新记录时，我会得到一个“无效的参数类型”。

它只需要将值连接到查询中就可以很好地工作，但是为了防止SQL注入，我需要一个参数化的查询。我尝试用值替换ADO数据类型，但这没有改变任何东西。我尝试过未命名参数，它总是向数据库提交一个值16，而不是所需的字符串值

Private Sub Worksheet_Change(ByVal Target As Range)
        ID = Cells(Target.Row, 1).Value
        Dim locValue As String
        locValue = Cells(Target.Row, 2).Value

        Dim Cm As ADODB.Command
        Set Cm = New ADODB.Command

        Cm.NamedParameters = True
        Cm.CommandText = "UPDATE issues SET " _
        & "location = @location " _
        & "WHERE id = " & ID

        Dim locationParameter As ADODB.Parameter

        Set locationParameter = Cm.CreateParameter("@location", adVarChar, adParamInput, 255)
        Cm.Parameters.Append locationParameter
        locationParameter.Value = locValue

        SqlConnection(Cm)
End Sub

（我知道ID还没有参数化，问题出在位置上）

Public Function SqlConnection(Cm As ADODB.Command) As ADODB.Recordset
 Dim Cn As ADODB.Connection
    Dim Server_Name As String
    Dim Database_Name As String
    Dim User_ID As String
    Dim Password As String
    Dim SQLStr As String

    Server_Name = "127.0.0.1" ' Enter your server name here
    Database_Name = "issues_and_outages" ' Enter your  database name here
    User_ID = "root" ' enter your user ID here
    Password = "password" ' Enter your password here

    Set Cn = New ADODB.Connection
    Cn.Open "Driver={MySQL ODBC 8.0 ANSI Driver};Server=" & Server_Name & ";Database=" & Database_Name & _
    ";Uid=" & User_ID & ";Pwd=" & Password & ";"

    Cm.CommandType = adCmdText
    Cm.ActiveConnection = Cn

    Set SqlConnection = Cm.Execute

End Function

服务器是MySQL，有一个issues_and_ougages表，其中列有：

>

ID（整数、无符号、键、auto_increment)

位置(varchar(255)，可为空）

更新单元格（单元格应更新位置列）时，错误为

“运行时错误”-2147217887(80040E21)“：[MySQL][ODBC 8.0(a)驱动程序][MySQLD-8.0.16]无效的参数类型”

是给定的，但在cm.execute行上有一个错误。但是，数据库有一个大小为255的varchar类型列，它应该是adVarChar，所以我不希望出现错误。

Answer 1

正如我们经常讨论的那样，大多数提供程序/驱动程序的ADO API不支持非存储过程SQL语句的命名参数。而是使用qmark,positional参数样式。

Set Cm = New ADODB.Command

With Cm
    .ActiveConnection = Cn
    .CommandType = adCmdText
    .CommandText = "UPDATE issues SET location = ? WHERE id = ?"

    .Parameters.Append .CreateParameter("loc_param", adVarChar, adParamInput, 255, locValue)
    .Parameters.Append .CreateParameter("id_param", adInteger, adParamInput,, ID)

    .Execute
End With