如何在OpenOffice.Org Calc的单元格公式中调用Python宏？

Question

为了扩展OpenOffice的功能，我在用户脚本目录（在本例中为〜/
Library / Application Support / OpenOffice.org / 3 / user / Scripts / python
/）的文件中定义了一些Python宏。这些宏在Python宏组织器中可见。但是，在单元格公式中使用这些功能会导致“ #NAME？”
（OO.org错误525）。

假设我定义了以下函数：

def pytype(val):
    return str(type(val))

如何调用pytype单元格公式（例如=PYTYPE("string")）？

背景

我正在从Authorize.net导入一些数据到MySQL数据库中进行分析。MySQL无法将Authorize.net使用的日期和时间格式解析为DATETIMEorTIMESTAMP字段，因此我试图将数据整理为MySQL可以在导入之前处理的格式。OpenOffice也不将数据识别为日期和时间，据我所知，OO.Org没有通用的日期解析功能。因此，我正在扩展OO.org的功能。

对于更大的问题，还有其他方法。例如，我还可以尝试使用其他列来修复MySQL导入后的数据。实际上，这是我第一次做。但是，表中现在有需要解决的数据。因此，由于将来还有其他任务，我希望通过在公式中使用宏来完成，目前，我最感兴趣的是在公式中调用Python宏。

Answer 1

在旧的OO.org论坛上，（超级）用户Villeroy发布了有关如何从OO.org
Basic
调用Python函数的说明，然后可将其用于公式中。关键是将com.sun.star.script.provider.MasterScriptProviderFactory服务用作桥梁。这是他的解决方案的改编版，可概括为在任意模块中调用任意函数：

REM Keep a global reference to the ScriptProvider, since this stuff may be called many times: 
Global g_MasterScriptProvider as Object
REM Specify location of Python script, providing cell functions: 
Const URL_Main as String = "vnd.sun.star.script:" 
Const URL_Args as String = "?language=Python&location=user"

Function invokePyFunc(file AS String, func As String, args As Array, outIdxs As Array, outArgs As Array)
   sURL = URL_Main & file & ".py$" & func & URL_Args
   oMSP = getMasterScriptProvider()
   On Local Error GoTo ErrorHandler
      oScript = oMSP.getScript(sURL)
      invokePyFunc = oScript.invoke(args, outIdxs, outArgs)
      Exit Function
   ErrorHandler:
      Dim msg As String, toFix As String
      msg = Error$
      toFix = ""
      If 1 = Err AND InStr(Error$, "an error occurred during file opening") Then
         msg = "Couldn' open the script file."
         toFix = "Make sure the 'python' folder exists in the user's Scripts folder, and that the former contains " & file & ".py."
      End If
      MsgBox msg & chr(13) & toFix, 16, "Error " & Err & " calling " & func
end Function

Function getMasterScriptProvider() 
   if isNull(g_MasterScriptProvider) then 
      oMasterScriptProviderFactory = createUnoService("com.sun.star.script.provider.MasterScriptProviderFactory") 
      g_MasterScriptProvider = oMasterScriptProviderFactory.createScriptProvider("") 
   endif 
   getMasterScriptProvider = g_MasterScriptProvider
End Function

然后可以使用它来创建可在公式中调用的OO.org Basic函数。使用示例pytype：

Const libfile as String = "util"    REM functions live in util.py

Function pytype(value)
    pytype = invokePyFunc(libfile, "pytype", Array(value), Array(), Array())
End Function

另一个可能的实现是创建一个Python加载项。但是，这是一个繁重的选择，因为它需要安装OpenOffice
SDK，并且对于这种方法是适用于免费功能还是仅适用于类，这对我来说并不明显。