在Grails战争中添加“精简” Groovy Web控制台

谷梁俊楚

2023-12-01

假设您已将Grails应用程序部署到服务器上–如何查找应用程序的配置方式？如果您有来源，则可以查看Config.groovy ， BuildConfig.groovy等（在这种情况下，我正在谈论Grails 2应用程序，但是这些想法可以推广到Grails 3+），但这通常还不够。

Grails 2支持外部配置文件，该文件可以在不同的地方并合并到最终配置中。但是仅仅拥有您认为正确的源文件和配置文件是不够的，因为可能已经进行了一些更改，而这些更改并未纳入源代码管理中。而且，由于它们已被编译为类，因此您无法轻易地从WAR中的这些文件中获取信息。

我更喜欢挖掘正在运行的Grails应用程序是控制台插件，但要使用该插件，您需要将其添加到BuildConfig.groovy并构建和部署新的WAR，但这又不一定与先前的配置相同。部署。

我在工作时遇到这种情况，因此我想出了一种轻巧的方法，可以将类似于控制台插件的基于Web的控制台添加到WAR中。最初，它是一个servlet，它以一种简单的形式生成HTML，其中包含用于Groovy代码的文本区域和用于提交要在服务器上运行的代码的提交按钮，以及用于执行该代码的逻辑（主要是从控制台插件借来的）返回结果到浏览器。我在构建WAR的同一项目中对其进行了编译，以确保它与Groovy，Grails，Spring等版本兼容，然后将.class文件复制到Tomcat的webapps文件夹的展开目录中的WEB-INF/classes中。，并手动编辑WEB-APP/web.xml以添加所需的<servlet>和<servlet-mapping>元素，并且在我的小型测试应用程序中一切正常。

但是当我在真实的应用程序中尝试它时，由于Spring Security的缘故，我无法访问它。在这种特殊情况下，我可以解决该问题，因为该应用程序将Requestmap实例存储在数据库中，但是我不想进行可能忘记撤消的更改，并且存在鸡与蛋的问题必须知道此部署的数据库设置是什么。因此，我改为将servlet转换为servlet过滤器，并确保将过滤器添加到web.xml的Spring Security过滤器链之前，并在重新启动服务器后按预期工作。

我在爆炸的war目录中进行了更改，但是也可以在WAR文件本身中进行更改。由于WAR文件是ZIP文件，因此您可以解压缩WAR，进行更改并重新压缩。

这是过滤器的来源：

package com.burtbeckwith.hack

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import org.codehaus.groovy.grails.commons.GrailsApplication
import org.springframework.context.ApplicationContext
import org.springframework.web.context.support.WebApplicationContextUtils

import javax.servlet.Filter
import javax.servlet.FilterChain
import javax.servlet.FilterConfig
import javax.servlet.ServletException
import javax.servlet.ServletRequest
import javax.servlet.ServletResponse
import javax.servlet.http.HttpServletRequest
import javax.servlet.http.HttpServletResponse

@CompileStatic
@Slf4j
class HackFilter implements Filter {

   private ApplicationContext applicationContext
   private GrailsApplication grailsApplication

   void init(FilterConfig fc) throws ServletException {
      applicationContext = WebApplicationContextUtils.getRequiredWebApplicationContext(fc.servletContext)
      grailsApplication = applicationContext.getBean(GrailsApplication)
   }

   void doFilter(ServletRequest req, ServletResponse res, FilterChain chain) throws IOException, ServletException {
      HttpServletRequest request = (HttpServletRequest) req
      HttpServletResponse response = (HttpServletResponse) res

      if ('GET' == request.method) {
         doGet request, response
      }
      else {
         // assume POST
         doPost request, response
      }
   }

   void destroy() {}

   private void doGet(HttpServletRequest request, HttpServletResponse response) throws ServletException, IOException {
      response.writer.write html(request.contextPath)
   }

   private void doPost(HttpServletRequest request, HttpServletResponse response) throws ServletException, IOException {
      long startTime = System.currentTimeMillis()

      String code = request.getParameter('code')

      ByteArrayOutputStream baos = new ByteArrayOutputStream()
      PrintStream out = new PrintStream(baos)
      PrintStream systemOut = System.out

      Throwable e
      String result = ''
      try {
         System.out = out
         result = new GroovyShell(grailsApplication.classLoader, new Binding(
               config: grailsApplication.config,
               ctx: applicationContext,
               grailsApplication: grailsApplication,
               out: out,
               request: request,
               session: request.session)).evaluate(code)
      }
      catch (Throwable t) {
         e = t
      }
      finally {
         System.out = systemOut
      }

      if (e) {
         StringWriter sw = new StringWriter()
         e.printStackTrace new PrintWriter(sw)
         result = sw.toString().replace('\t', '   ').replace(System.getProperty('line.separator'), '<br/>\n')
      }

      response.writer << html(request.contextPath, code, """\
Total time: ${System.currentTimeMillis() - startTime}ms

Stdout:
${baos.toString('UTF8')}

${e ? 'Exception' : 'Result'}:
$result""")
   }

   private String html(String contextPath, String code = '', String results = '') {
      """\
<html>
<head>
<title>Hack</title>
</head>
<body>
   <form action="$contextPath/hack" method="POST">
      <span>Code: (binding vars include <i>config</i>, <i>ctx</i>, <i>grailsApplication</i>, <i>out</i>, <i>request</i>, <i>session</i>)</span><br/>
      <textarea name="code" cols="120" rows="25">$code</textarea><br/>
      <input type="submit" value="Execute" name="execute" /><br/>
      <span>Results:</span><br/>
      <textarea name="results" cols="120" rows="25" disabled="disabled">$results</textarea>
   </form>
</body>
</html>
"""
   }
}

这些是web.xml的相应<filter>和<filter-mapping>元素：

<filter>
   <filter-name>hack</filter-name>
   <filter-class>com.burtbeckwith.hack.HackFilter</filter-class>
</filter>
<filter-mapping>
   <filter-name>hack</filter-name>
   <url-pattern>/hack</url-pattern>
</filter-mapping>

要访问控制台，请导航至http：// server：port / contextPath / hack。与在控制台插件中一样，您可以运行任意Groovy代码（包括服务方法调用，使用域类等），并且在绑定中可以使用多个对象– config ， ctx ， grailsApplication ， out ， request和session 。

要将uri从/ hack更改为其他内容，请确保同时更新web.xml的<url-pattern>标签和过滤器类中生成的表单中的action属性。

假设您已将Grails应用程序部署到服务器上–如何查找应用程序的配置方式？如果您有资料来源，那么您……

此条目发布于2017年12月7日星期四上午8:23，并根据grails ， groovy ， java ， security提交。您可以通过RSS 2.0 feed跟踪对此条目的任何响应。您可以在自己的网站上留下回复（审核审核）或引用。

翻译自: https://www.javacodegeeks.com/2017/12/adding-lite-groovy-web-console-grails-war.html

在Grails战争中添加“精简” Groovy Web控制台

相关阅读

相关文章

相关问答

相关文档