登录
当前位置： 首页 > 编程笔记 >

vbs脚本实现批量转换文件编码

汪典
2023-03-14
本文向大家介绍vbs脚本实现批量转换文件编码，包括了vbs脚本实现批量转换文件编码的使用技巧和注意事项，需要的朋友参考一下

最近需要使用SourceInsight查看分析在Linux系统下开发的项目代码，我们知道Linux系统中文本文件默认编码格式是UTF-8，而Windows中文系统中的默认编码格式是Gb2312。系统内的编码格式有所区别倒无伤大雅，关键的是SourceInsight竟不支持UTF-8，导致项目代码内的中文注释全部乱码！

既然SourceInsight不支持UTF-8编码的文件，那我们就得想办法将UTF-8的代码文件转化为GB2312编码的。首先想到的是到网上搜一下“批量编码转换工具”，结果下载后发现编码转换后的文件总是出现乱码，可能是工具的bug吧。既然不能使用工具转换，那就自己写一个程序进行编码转换，但是细想一下觉得C++/html" target="_blank">java的编码转换程序写起来又比较啰嗦，要是在Linux下写一个shell脚本就能轻松搞定了。还好Windows下有vbs脚本可以帮助我们轻松达到这个目的。

'-------------------------------------------------


'函数名称:ReadFile


'作用:利用AdoDb.Stream对象来读取各种格式的文本文件


'-------------------------------------------------


 


Function ReadFile(FileUrl, CharSet)


    Dim Str


    Set stm = CreateObject("Adodb.Stream")


    stm.Type = 2


    stm.mode = 3


    stm.charset = CharSet


    stm.Open


    stm.loadfromfile FileUrl


    Str = stm.readtext


    stm.Close


    Set stm = Nothing


    ReadFile = Str


End Function

我们使用ReadFile函数读取文件，其中FileUrl指定文件的路径，CharSet指定文件的原始编码格式，使用adodb.stream对象读取文件内容到Str。

'-------------------------------------------------


'函数名称:WriteToFile


'作用:利用AdoDb.Stream对象来写入各种格式的文本文件


'-------------------------------------------------


 


Function WriteToFile (FileUrl, Str, CharSet)


    Set stm = CreateObject("Adodb.Stream")


    stm.Type = 2


    stm.mode = 3


    stm.charset = CharSet


    stm.Open


    stm.WriteText Str


    stm.SaveToFile FileUrl, 2


    stm.flush


    stm.Close


    Set stm = Nothing


End Function

然后使用WriteToFile将Str写回原文件FileUrl，并设定新的编码CharSet。

'-------------------------------------------------


'函数名称:ConvertFile


'作用:将一个文件进行编码转换


'-------------------------------------------------


 


Function ConvertFile(FileUrl)


    Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)


End Function

这样ConvertFile对上述两个函数封装，实现文件FileUrl的编码转换，其中原始编码SrcCode与目的编码DestCode为全局变量。

如果仅对一个文件进行编码转换，我们不必这么大费周章。我们希望能对任意的文件或文件夹内的所有文件进行编码转换，达到批量转换的目的。

'-------------------------------------------------


'函数名称:ConvertDir


'作用:将任意目录内的文件进行编码转换


'-------------------------------------------------


 


Function ConvertDir(DirUrl)


    If fs.FileExists(DirUrl) Then 


       Call ConvertFile(DirUrl)


    Else


       Call SearchDir(DirUrl)


    End If


End Function

函数ConvertDir对任意路径的文件/文件夹进行编码转换，使用scripting.filesystemobject对象的FileExists函数判断路径对应的是文件还是文件夹，如果是文件则直接调用ConvertFile进行编码转换，否则调用SearchDir处理文件夹。

'-------------------------------------------------


'函数名称:SearchDir


'作用:递归查找目录内的文件，进行编码转换


'-------------------------------------------------


 


Function SearchDir(path)   


    Set folder = fs.getfolder(path)


    Set subfolders = folder.subfolders


    Set Files = folder.Files   


    For Each i In Files


       Call ConvertFile(i.path)


    Next   


    For Each j In subfolders       


       Call SearchDir(j.path)


    Next


End Function

函数SearchDir是递归的，首先调用getfolder创建文件夹对象，然后取出文件夹内的子文件夹集合subfolders和子文件集合files。对于每个子文件，直接调用ConvertFile进行编码转换即可，而对于每个子文件夹，则递归调用SearchDir重复处理。

'-------------------------------------------------


'设置编码：默认 utf-8  --> gb2312


'-------------------------------------------------


 


SrcCode="utf-8"


DestCode="gb2312"


 


'-------------------------------------------------


'解析参数


'-------------------------------------------------


 


Set fs = CreateObject("scripting.filesystemobject")


Set objArgs = WScript.Arguments


If objArgs.Count>0 Then


    For I = 0 To objArgs.Count - 1


       FileUrl = objArgs(I)


       Call ConvertDir(FileUrl)


    Next


Else


    MsgBox "没有文件/文件夹被拖入！"


    wscript.quit


End If


MsgBox "转换成功！"

最后通过解析脚本文件的参数，由于每个参数对应一个文件/文件夹的路径，将之传递给ConvertDir即可。这里默认的是将UTF-8编码转化为GB2312编码，读者可以根据自身需要自行修改。

将上述代码保存为ConvertCode.vbs，只需要将任意多个文件选中拖动到该脚本文件上即可。或者使用命令行。

> ConvertCode.vbs [filepath]

需要注意的是文件编码是就地转换的，在转换之前最好将原文件/文件夹进行备份。

最后附上脚本文件的所有代码。

'/*===========================================================
' * Intro        把要转换的多个文件/文件夹拖到该文件上即可
' * FileName     ConvertCode.vbs
' * Author       Florian
' * Version      v1.0
' * LastModify  2014-06-11 00:39:58
' *==========================================================*/


'-------------------------------------------------
'设置编码：默认    utf-8    -->    gb2312
'-------------------------------------------------


SrcCode="utf-8"
DestCode="gb2312"


'-------------------------------------------------
'解析参数
'-------------------------------------------------


Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
    For I = 0 To objArgs.Count - 1
        FileUrl = objArgs(I)
        Call ConvertDir(FileUrl)
    Next
Else
    MsgBox "没有文件/文件夹被拖入！"
    wscript.quit
End If
MsgBox    "转换成功！"


'-------------------------------------------------
'函数名称:ConvertDir
'作用:将任意目录内的文件进行编码转换
'-------------------------------------------------


Function ConvertDir(DirUrl)
    If fs.FileExists(DirUrl) Then  
        Call ConvertFile(DirUrl)
    Else
        Call SearchDir(DirUrl)
    End If
End Function



'-------------------------------------------------
'函数名称:SearchDir
'作用:递归查找目录内的文件，进行编码转换
'-------------------------------------------------


Function SearchDir(path)    
    Set folder = fs.getfolder(path)
    Set subfolders = folder.subfolders
    Set Files = folder.Files    
    For Each i In Files
        Call ConvertFile(i.path)
    Next    
    For Each j In subfolders        
        Call SearchDir(j.path)
    Next
End Function


'-------------------------------------------------
'函数名称:ConvertFile
'作用:将一个文件进行编码转换
'-------------------------------------------------


Function ConvertFile(FileUrl)
    Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function


'-------------------------------------------------
'函数名称:ReadFile
'作用:利用AdoDb.Stream对象来读取各种格式的文本文件
'-------------------------------------------------


Function ReadFile(FileUrl, CharSet)
    Dim Str
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.loadfromfile FileUrl
    Str = stm.readtext
    stm.Close
    Set stm = Nothing
    ReadFile = Str
End Function


'-------------------------------------------------
'函数名称:WriteToFile
'作用:利用AdoDb.Stream对象来写入各种格式的文本文件
'-------------------------------------------------


Function WriteToFile (FileUrl, Str, CharSet)
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.WriteText Str
    stm.SaveToFile FileUrl, 2
    stm.flush
    stm.Close
    Set stm = Nothing
End FunctionView Code

 类似资料：
  • VBS脚本实现遍历批量替换多目录多文件内容的代码

    本文向大家介绍VBS脚本实现遍历批量替换多目录多文件内容的代码，包括了VBS脚本实现遍历批量替换多目录多文件内容的代码的使用技巧和注意事项，需要的朋友参考一下 有时候我们需要将一个目录与子目录中的多个htm网页文件实现批量替换，这里就为大家分享一下 将以下代码复制到一个文本文档中，并将文本文档的后缀修改为.vbs，直接运行即可 cmd /c dir /s/b *.htm > list.htm就是将

  • Python批量转换文件编码格式

    本文向大家介绍Python批量转换文件编码格式，包括了Python批量转换文件编码格式的使用技巧和注意事项，需要的朋友参考一下 自己写的方法，适用于linux， py2.6以下版本可用代码 支持py3.1的版本 以上所述就是本文 的全部内容了，希望大家能够喜欢。

  • ass2srt.vbs(ass/ssa批量转换srt的脚本)

    本文向大家介绍ass2srt.vbs(ass/ssa批量转换srt的脚本)，包括了ass2srt.vbs(ass/ssa批量转换srt的脚本)的使用技巧和注意事项，需要的朋友参考一下 iPad中的OPlayer只支持srt格式的字幕，而动画一般使用的是ass/ssa格式的字幕，所以需要将ass/ssa批量转换srt。 Google了一下，在《ass2srt[ass/ssa批量转换srt]》中找到一

  • python实现快速文件格式批量转换的方法

    本文向大家介绍python实现快速文件格式批量转换的方法，包括了python实现快速文件格式批量转换的方法的使用技巧和注意事项，需要的朋友参考一下 用python实现文件夹下的成批文件格式转换 我们对于文件转换的需求很大，甚至于对于图片的格式，JPG和PNG格式在肉眼看来都没什么差别，但是对于计算机而言，它有时候就只接受这些肉眼看起来差不多的格式的其中一种。 环境 windows10 python

  • Shell脚本遍历目录并批量修改文件编码

    本文向大家介绍Shell脚本遍历目录并批量修改文件编码，包括了Shell脚本遍历目录并批量修改文件编码的使用技巧和注意事项，需要的朋友参考一下 在将windows上的jsp网页移植到linux环境中时，发现一个个的转换编码及修改默认编码类型太慢，写此脚本进行尝试文件遍历~ 好久不写，手生了。 当然，上面的代码由于使用了函数循环调用，显的很臃肿。下面来一种简单的方法,find一下：

  • vbs脚本实现修改DNS和清空IE临时文件功能

    本文向大家介绍vbs脚本实现修改DNS和清空IE临时文件功能，包括了vbs脚本实现修改DNS和清空IE临时文件功能的使用技巧和注意事项，需要的朋友参考一下 今早接到山青院电话，说需要一个修改DNS为校内DNS，并且清空IE临时文件的脚本，想都没想，用批处理写了一个： 你瞧，思路很简单，用netsh把dns改了就是了，因为要适应Win7跟Xp临时目录的不同，于是删除语句写了两遍。 但是，仔细想想，这

相关阅读

Shell脚本遍历目录并批量修改文件编码vbs脚本实现修改DNS和清空IE临时文件功能java实现文件编码转换的方法BAT批量去除文件首行以及批量合并文件脚本Python实现批量下载文件

相关文章

实战-Swing实现文件夹浏览Cassandra批量百度实习转提前批（OC）VBA文本文件JavaScript之原生拖放（HTML5脚本编程）

相关问答

从python脚本编写Json文件[重复]从ANSI到UTF8的Java文件编码转换Python中.dbf到.csv的批量转换.vbs脚本在批处理文件中运行，但在通过任务计划程序运行时不运行文件不会移动到文件夹vbs

相关工具

iPhone XIB资源批量转换iPad使用Shell脚本批量打包生成可配置的.ipa文件Stunnix VBS-ObfusJOE文本编辑器Monster 脚本

相关文档

高级 Bash 脚本编程指南Shell 脚本编程 30 分钟入门Shell 脚本学习精通脚本黑客本地组策略编辑器 帮助文档
快捷导航： 新手教程 算法原理 架构设计 Java进阶 数据库进阶 大厂专栏 面试经验 编程笔记 编程问答 所有专题 文档资料 工具软件 电子书籍 小牛导航
在线工具： 房贷计算器 个税计算器 Linux命令查询 Json格式化 正则表达式 颜色转换 AES加解密 SHA1加密 MD5加密 毒鸡汤 字数统计 随机密码生成 进制转换 Base64编解码 励志句子
Copyright © 2019-2024 小牛知识库@xnip.cn. All Rights Reserved.